透明度混合

AlphaBlend透明混合原理：
透明混合使用当前片元的透明度作为混合因子，与已存储在颜色缓冲中的颜色值进行混合，得到新的颜色。需要注意的是，透明度混合需要关闭深度写入，这时候要注意物体的渲染顺序。
这个图是关闭深度写入得到的效果。

这个是未关闭深度写入的效果，可以看出，渲染顺序已经完全乱套了。

关闭深度入
ZWrite off
设Tags
RenderType=Transparent
计算透明度
Return fixed4 （color，texColor.a*_AlphaScale）
设置混合模式
Blend SrcAlpha OneMinusScrAlpha

Shader "Unity/AlphaBlent"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _Color("Color",Color) =(1,1,1,1)
        _AlphaScale("AlphaScale",Range(0,1))=1
        _Cutoff("Cutoff",float)=0
    }
    SubShader
    {
        Tags{"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
        LOD 100
        ZWrite Off
        Blend SrcAlpha OneMinusSrcAlpha
        Pass
        {
            //开启深度写入
            ZWrite On
            //不写入任何颜色通道
            ColorMask 0
        }
        Pass
        {
            Tags{"LightMode"="ForwardBase" }
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            sampler2D _MainTex;
            fixed4 _MainTex_ST;
            fixed4 _Color;
            float  _AlphaScale;
            float _Cutoff;
            struct v2f
            {
                float4 vertex:SV_POSITION;
                float2 uv:TEXCOORD0;
                float3 worldPos:TEXCOORD1;
                float3 worldNormal:TEXCOORD2;
            };

            v2f vert(appdata_base v)
            {
                v2f o;
                o.vertex=UnityObjectToClipPos(v.vertex);
                o.uv=TRANSFORM_TEX(v.texcoord,_MainTex);
                o.worldPos=mul(unity_ObjectToWorld,v.vertex);
                o.worldNormal=UnityObjectToWorldNormal(v.normal);
                return o;
            };

            fixed4 frag(v2f i ):SV_TARGET
            {
                float3 WorldNormalDir=normalize(i.worldNormal);
                float3 WorldLightDir=normalize(UnityWorldSpaceLightDir(i.worldPos));
                //采样主贴图纹理
                float4 texColor= tex2D(_MainTex,i.uv);
                //计算环境光
                float3 ambient=UNITY_LIGHTMODEL_AMBIENT.rgb*texColor.rgb;
                //计算漫反射
                float3 diffuse=_LightColor0.rgb*texColor.rgb*_Color.rgb*(dot(WorldNormalDir,WorldLightDir)*0.5+0.5);
                fixed3 color=diffuse+ambient;
                return fixed4(color,texColor.a*_AlphaScale);
            };
            ENDCG
        }
    }
    Fallback "Transparent/Cutout/VertexLit"
}