Unity Shader 逐像素Phong高光反射（七）

Unity Shader系列文章：Unity Shader目录-初级篇

Unity Shader系列文章：Unity Shader目录-中级篇

效果：

Phong逐像素光照.jpg

Phong逐顶点光照、Phong逐像素光照、Blinn-Phong逐像素光照：

Phong逐顶点光照、Phong逐像素光照、Blinn-Phong逐像素光照.jpg

Phong高光反射公式：

：入射光颜色；
：高光反射颜色；
：单位视线向量；
：单位反射向量，可以由表面法线和光源方向计算而得：
= 2( . ) - ，CG中可直接使用reflect获得；
：反射系数；

Shader代码：

// Phong逐像素高光反射
Shader "Custom/Specular/PhongSpecularPixel"
{
    Properties
    {
        _Diffuse ("Diffuse", Color) = (1, 1, 1, 1) // 漫反射颜色
        _Specular ("Specular", Color) = (1, 1, 1, 1) // 高光反射颜色
        _Gloss ("Gloss", Range(8, 256)) = 20 // 高光区域大小
    }
    
    SubShader
    {
        Tags { "RenderType" = "Opaque" }
        LOD 100
        
        pass
        {
            Tags { "LightMode" = "ForwardBase" }
            
            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag
            
            #include "Lighting.cginc"
            
            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;
            
            // 应用传递给顶点着色器函数的数据
            struct a2v
            {
                float4 vertex: POSITION;
                fixed3 normal: NORMAL;
            };
            
            // 顶点着色器函数传递给片元着色器
            struct v2f
            {
                float4 pos: SV_POSITION;
                fixed3 worldNormal: TEXCOORD0;
                fixed3 worldPos: TEXCOORD1;
            };
            
            // 顶点着色器函数
            v2f vert(a2v v)
            {
                v2f o;
                // 将顶点坐标从模型空间变换到世界空间
                // 等价于o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
                o.pos = UnityObjectToClipPos(v.vertex);
                
                // 将法线从模型空间变换到世界空间，然后归一化
                // 等价于o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                
                // 将顶点从模型空间变换到世界空间
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
                
                return o;
            }
            
            // 片段着色器函数
            fixed4 frag(v2f i): SV_TARGET
            {
                // 获得世界空间下单位光向量
                float3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                
                // 计算漫反射
                // 兰伯特公式：Id = Ip * Kd * N * L
                // IP：入射光的光颜色；
                // Kd：漫反射系数 ( 0 ≤ Kd ≤ 1)；
                // N：单位法向量，L：单位光向量
                float3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(i.worldNormal, worldLightDir));
                
                // 计算反射方向
                // CG的reflect函数的入射方向要求是顶点指向光源，所以先取反
                float3 reflectDir = normalize(reflect(-worldLightDir, i.worldNormal));
                
                // 计算观察方向
                float3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);
                
                // 计算高光反射
                // Phong高光反射公式：
                // Cspecular=(Clight ⋅ Mspecular)max(0,v.r)^mgloss
                // Clight：入射光颜色；
                // Mspecular：高光反射颜色；
                // v：单位视线向量；
                // r：单位反射向量，可以由表面法线n和光源方向l计算而得：
                // r = 2(n . I)n - I; CG中可直接使用reflect获得
                // mgloss：反射系数；
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir, viewDir)), _Gloss);
                
                // 获得环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                return float4(ambient + diffuse + specular, 1);
            }
            
            ENDCG
            
        }
    }
}