AutoHotKey技巧2：窗口三分屏快捷键

用途

因为自己使用的是21:9的超宽带鱼屏，写文档的时候利用Windows自身左右分屏功能就显得有点浪费，而同时并列3个窗口刚刚好，所以利用AutoHotKey写出了一个脚本，可以通过快捷键来快速实现当前窗口3分屏。

脚本内容

Split3(num)                        ;当前窗口三分屏函数
{
    w := A_ScreenWidth/3+15         ;窗口宽度=屏幕横像素/3+15，直接除以3，3个窗口排不满，原因未知
    h := A_ScreenHeight             ;窗口高度=屏幕纵像素
    pox_y = 0                       ;窗口位置纵坐标=0，即窗口放到最顶部

    if (num=1)
        pos_x = 0                   ;如果1，则窗口横坐标位置=0，即窗口放到屏幕左上角，宽度为1/3屏幕，高度为屏幕高度
        
    else if(num=2)
        pos_x := A_ScreenWidth/3
        
    else if(num=3)
        pos_x := A_ScreenWidth/3*2
        
    else if(num=4)
    {
        pos_x := 0
        w := A_ScreenWidth/3*2+15
    }
        
    else if(num=6)
    {
        pos_x := A_ScreenWidth/3
        w := A_ScreenWidth/3*2+15    ;其他的同理
    }
    else   
        return                      ;如果函数传入其他数字，则return退出函数
    
    WinRestore A                    ;如果当前窗口为最大化或者最小化状态，直接使用WinMove函数是不能移动和改变其大小的
                                    ;所以先使用WinRestore取消其最大化或者最小化状态，A表示当前窗口
    WinMove, A,, pos_x, pox_y, w, h ;调用WinMove函数，按照设定值改变窗口位置和大小
}

^!Numpad1:: Split3(1)
^!Numpad2:: Split3(2)
^!Numpad3:: Split3(3)
^!Numpad4:: Split3(4)
^!Numpad6:: Split3(6)

使用

安装AutoHotKey，新建文本贴入上述代码并保存成xxx.ahk，双击脚本文件，这样就已经在后台运行了。

效果

ctrl+alt+数字键盘1：1/3窗口靠屏幕左边
ctrl+alt+数字键盘2：1/3窗口靠屏幕中间
ctrl+alt+数字键盘3：1/3窗口靠屏幕右边
ctrl+alt+数字键盘4：2/3窗口靠屏幕左边
ctrl+alt+数字键盘6：2/3窗口靠屏幕右边

三分屏.png