摩擦力

书名：代码本色：用编程模拟自然系统
作者：Daniel Shiffman
译者：周晗彬
ISBN：978-7-115-36947-5
目录

2.7　摩擦力

  

1、摩擦力

• 摩擦力是一种耗散力。
• 耗散力的定义是：在运动中使系统总能量减少的力。
  比如说，开车时，脚踩刹车板会让车通过摩擦力使轮胎减速，在这个过程中，动能被转化为热能。
• 只要两个物体的表面相互接触，它们之间就有摩擦力。
• 摩擦力可分为静摩擦力（物体相对表面静止不动）和动摩擦力（物体在表面上运动），但我们只探讨有关动摩擦力的话题。

2、摩擦力的力学公式：

图2-3

• 我们可以将公式分成两部分，一部分用于确定摩擦力的方向，另一部分用于确定摩擦力的大小。
• 从上面的插图可以看出：摩擦力的方向和物体运动的方向相反。实际上，公式中的也说明了这一点，它表示速度的单位向量乘以-1。
• 在Processing中，我们要先将速度向量单位化，再将单位向量乘以-1。

PVector friction = velocity.get();
friction.normalize();
friction.mult(-1); 计算摩擦力的方向（与速度方向相反的单位向量）

注意，上面的代码有两个额外的步骤：

• 首先，复制一份速度向量对象，因为我们不能直接改变速度向量，不能突然让物体朝着相反的方向运动；
• 其次，将向量单位化，因为摩擦力的大小和物体运动的速度无关，而用单位向量能让整个计算过程变简单。

3、摩擦系数

• 摩擦力的大小等于μ*N，希腊字母μ表示摩擦系数。
• 摩擦系数代表特定表面的摩擦力强度。系数越高，摩擦力越强；系数越低，摩擦力越弱。
  比如，冰面的摩擦系数就比砂纸的摩擦系数低很多。
• 在Processing构建的模拟世界中，我们可以随便确定一个数字作为摩擦系数。
  float c = 0.01;

4、压力

• N代表正向力，它指的是物体垂直于表面的压力。
• 牛顿第三定律告诉我们路面对汽车也有一个向上的反作用力，这个力就是正向力。
• 重力越大，正向力也越大。
• 重力和质量相关，所以一辆超轻跑车所受的摩擦力比大型拖拉机所受的摩擦力小。
• 上图中，物体在倾斜的表面运动，在这种情况下，正向力的计算方式有些复杂，因为它和重力的方向并不相同，在计算之前，我们还需要掌握角度和三角函数的知识。

5、把摩擦力加入程序

除了风力和重力，对象现在还受摩擦力的作用
示例代码2-4 加入摩擦力

Mover[] movers = new Mover[5];

void setup() {
  size(383, 200);
  randomSeed(1);
  for (int i = 0; i < movers.length; i++) {
    movers[i] = new Mover(random(1, 4), random(width), 0);
  }
}

void draw() {
  background(255);

  for (int i = 0; i < movers.length; i++) {

    PVector wind = new PVector(0.01, 0);
    PVector gravity = new PVector(0, 0.1*movers[i].mass);

    float c = 0.05;
    PVector friction = movers[i].velocity.get();
    friction.mult(-1); 
    friction.normalize();
    friction.mult(c);

   if(movers[i].position.x > width / 2) {
      movers[i].applyForce(friction);  
    }
    //movers[i].applyForce(friction);
    movers[i].applyForce(wind);
    movers[i].applyForce(gravity);

    movers[i].update();
    movers[i].display();
    movers[i].checkEdges();
  }
}

Mover.pde

class Mover {

  PVector position;
  PVector velocity;
  PVector acceleration;
  float mass;
  color c;

  Mover(float m, float x , float y) {
    mass = m;
    position = new PVector(x,y);
    velocity = new PVector(0,0);
    acceleration = new PVector(0,0);
    c = color(random(255),random(255),random(255));
  }
  
  void applyForce(PVector force) {
    PVector f = PVector.div(force,mass);
    acceleration.add(f);
  }
  
  void update() {
    velocity.add(acceleration);
    position.add(velocity);
    acceleration.mult(0);
  }

  void display() {
    stroke(0);
    strokeWeight(2);
    //fill(0,127);
    fill(c);
    ellipse(position.x,position.y,mass*16,mass*16);
  }

  void checkEdges() {

    if (position.x > width) {
      position.x = width;
      velocity.x *= -1;
    } else if (position.x < 0) {
      position.x = 0;
      velocity.x *= -1;
    }

    if (position.y > height) {
      velocity.y *= -1;
      position.y = height;
    }

  }

}

运行这个程序，你会发现屏幕上的圆很难到达窗口的右边缘。因为在物体运动过程中，摩擦力会持续给它施加一个反向的作用效果，所以物体会减速。
这是一个有用的技术，你可以用它实现想要的视觉效果。