学习笔记
《x86汇编语言：从实模式到保护模式》
https://www.jianshu.com/p/d481cb547e9f
答案参考
https://blog.csdn.net/longintchar/article/details/51167487?locationNum=5&fps=1
本章习题
- 在本章中，用户程序只给出建议的栈大小，但并不提供栈空间。现在，修改内核程序和用户程序，改由用户程序自行提供栈空间。要求：栈段必须定义在用户程序之后。
习题解答
修改内核程序 c13_core.asm
;建立程序堆栈段描述符
mov ecx,[edi+0x0c] ;4KB的倍率
mov ebx,0x000fffff
sub ebx,ecx ;得到段界限
mov eax,4096
mul dword [edi+0x0c]
mov edx,edi
add edx,[edi+0x08]
add eax,edx ;得到栈的高端物理地址
mov ecx,0x00c09600 ;4KB粒度的堆栈段描述符
call sys_routine_seg_sel:make_seg_descriptor
call sys_routine_seg_sel:set_up_gdt_descriptor
mov [edi+0x08],cx
- 计算段界限
计算段界限
《x86汇编语言：从实模式到保护模式》 第237页
修改用户程序 c13.asm
usr_stack_len equ 1
usr_stack_cap equ usr_stack_len*0x1000 ; 0x1000 = 4096
;===============================================================================
SECTION header vstart=0
program_length dd program_end ;程序总长度#0x00
head_len dd header_end ;程序头部的长度#0x04
stack_seg dd section.stack.start ;用于接收堆栈段选择子#0x08
stack_len dd usr_stack_len ;程序建议的堆栈大小#0x0c
;以4KB为单位
prgentry dd start ;程序入口#0x10
code_seg dd section.code.start ;代码段位置#0x14
code_len dd code_end ;代码段长度#0x18
data_seg dd section.data.start ;数据段位置#0x1c
data_len dd data_end ;数据段长度#0x20
;-------------------------------------------------------------------------------
;符号地址检索表
salt_items dd (header_end-salt)/256 ;#0x24
salt: ;#0x28
PrintString db '@PrintString'
times 256-($-PrintString) db 0
TerminateProgram db '@TerminateProgram'
times 256-($-TerminateProgram) db 0
ReadDiskData db '@ReadDiskData'
times 256-($-ReadDiskData) db 0
header_end:
;===============================================================================
SECTION stack vstart=0
stack_start:
times usr_stack_cap db 0 ;4KB的栈空间
stack_end:
;===============================================================================
- 增加两个常量 用户程序栈的大小（以4KB为单位）
usr_stack_len以及 用户程序栈的容量usr_stack_cap； - 修改标号
stack_seg以及stack_len后面的初始值； - 增加段
SECTION stack，这样就由用户程序自己给自己提供栈空间；
Bochs 调试
- 从加载程序跳转到内核程序
由加载程序的
行数 汇编地址 机器码 汇编指令
136 00000138 FF6F10 jmp far [edi+0x10]
在 bochs使用
b 0x7d38
c
就可以跳转到 加载程序 转移控制权给 内核程序的这一条指令；
0x7d38 等于 0x7c00+0x138
- 执行内核程序的指令
来到内核程序之后，遇到的第一条指令是：
行数 汇编地址 机器码 汇编指令
561 00000159 B930000000 mov ecx,core_data_seg_sel
而这条指令的真实物理地址是 0x410a9
我希望直接跳到，加载完全部描述符的
这条指令：
503 000000EB 66894F08 mov [edi+0x08],cx
经过换算，可以得出，目标的真实物理地址
应该是 0x4103b
因此，在bochs里面使用
b 0x4103b
c
就可以跳转到这条指令了。
- 使用
info gdt查看GDT的内容，看到Expand-down字样说明加载栈段成功
Expand-dwon字样说明这是向下生长的数据段即栈段.png
栈段都是Expand-down.png
Debug
1、调试用户程序的时候，将某个SECTION的标号当做是从整个程序开头的偏移量了
标记了vstart=0 说明标号的值是从段开始的偏移量
2、实际测试 push pop
- 这里一开始忘记给字符串 message_test 最后加上 0 作为结尾，结果每次运行都死机，死机还死在不同的位置（就是显示的字符串数量完全不一样）
;===============================================================================
SECTION data vstart=0
buffer times 1024 db 0 ;缓冲区
message_1 db 0x0d,0x0a,0x0d,0x0a
db '**********User program is runing**********'
db 0x0d,0x0a,0
message_2 db ' Disk data:',0x0d,0x0a,0
message_test db 0x0d,0x0a,0x0d,0x0a
db '>>>>>> test stack pass <<<<<<',0x0d,0x0a,0
data_end:
;===============================================================================
;>>>>>>>>>>>> TEST STACK <<<<<<<<<<<<<<<<<<<<<<
push ecx
mov ecx,1000
testpush:
push ebx
loop testpush
mov ecx,1000
testpop:
pop ebx
loop testpop
pop ecx
mov ebx,message_test
call far [fs:PrintString]
;>>>>>>>>>>>> TEST STACK <<<<<<<<<<<<<<<<<<<<<<
实际测试用户程序的栈 测试结果
- 心得：以后如果要写有关测试的输出语句，就应该在代码可以正常运行的时候，先保证这条输出语句也可以正常运行，再去功能化新的代码，不然根本分不清是新代码的功能有缺陷还是输出语句本身错了，谁会想到一条简单的输出函数调用都会错，而且错是错在输出用的字符串这里，没错，这就是汇编。
完整源码
用户程序 c13.asm （第十三章 习题答案）
;代码清单13-3
;文件名：c13.asm
;文件说明：用户程序
;创建日期：21:58 2018/6/4
usr_stack_len equ 1
usr_stack_cap equ usr_stack_len*0x1000 ; 0x1000 = 4096
;===============================================================================
SECTION header vstart=0
program_length dd program_end ;程序总长度#0x00
head_len dd header_end ;程序头部的长度#0x04
stack_seg dd section.stack.start ;用于接收堆栈段选择子#0x08
stack_len dd usr_stack_len ;程序建议的堆栈大小#0x0c
;以4KB为单位
prgentry dd start ;程序入口#0x10
code_seg dd section.code.start ;代码段位置#0x14
code_len dd code_end ;代码段长度#0x18
data_seg dd section.data.start ;数据段位置#0x1c
data_len dd data_end ;数据段长度#0x20
;-------------------------------------------------------------------------------
;符号地址检索表
salt_items dd (header_end-salt)/256 ;#0x24
salt: ;#0x28
PrintString db '@PrintString'
times 256-($-PrintString) db 0
TerminateProgram db '@TerminateProgram'
times 256-($-TerminateProgram) db 0
ReadDiskData db '@ReadDiskData'
times 256-($-ReadDiskData) db 0
header_end:
;===============================================================================
SECTION stack vstart=0
stack_start:
times usr_stack_cap db 0 ;4KB的栈空间
stack_end:
;===============================================================================
SECTION data vstart=0
buffer times 1024 db 0 ;缓冲区
message_1 db 0x0d,0x0a,0x0d,0x0a
db '**********User program is runing**********'
db 0x0d,0x0a,0
message_2 db ' Disk data:',0x0d,0x0a,0
message_test db 0x0d,0x0a,0x0d,0x0a
db '>>>>>> test stack pass <<<<<<',0x0d,0x0a,0
data_end:
;===============================================================================
[bits 32]
;===============================================================================
SECTION code vstart=0
start:
mov eax,ds
mov fs,eax
mov eax,[stack_seg]
mov ss,eax
mov esp,0
mov eax,[data_seg]
mov ds,eax
mov ebx,message_1
call far [fs:PrintString]
mov eax,100 ;逻辑扇区号100
mov ebx,buffer ;缓冲区偏移地址
call far [fs:ReadDiskData] ;段间调用
mov ebx,message_2
call far [fs:PrintString]
mov ebx,buffer
call far [fs:PrintString] ;too.
;>>>>>>>>>>>> TEST STACK <<<<<<<<<<<<<<<<<<<<<<
push ecx
mov ecx,1000
testpush:
push ebx
loop testpush
mov ecx,1000
testpop:
pop ebx
loop testpop
pop ecx
mov ebx,message_test
call far [fs:PrintString]
;>>>>>>>>>>>> TEST STACK <<<<<<<<<<<<<<<<<<<<<<
jmp far [fs:TerminateProgram] ;将控制权返回到系统
code_end:
;===============================================================================
SECTION trail
;-------------------------------------------------------------------------------
program_end: