使用以太坊发布属于你自己的虚拟代币

本文从技术角度详细介绍如何基于以太坊ERC20创建代币的流程。

关于以太坊的编程语言Solidity的教学我就不做了（懒。。），Solidity教程在网上就能找到，我尽量做到，你们跟着我的魔鬼的步伐，一步一步就把代币做出来。

关于ERC20：

也许你经常看到ERC20和代币一同出现， ERC20是以太坊定义的一个代币标准。
要求我们在实现代币的时候必须要遵守的协议，如指定代币名称、总量、实现代币交易函数等，只有支持了协议才能被以太坊钱包支持。
其接口如下：

contract ERC20Interface {

    string public constant name = "Token Name";
    string public constant symbol = "SYM";
    uint8 public constant decimals = 18;  // 18 is the most common number of decimal places

    function totalSupply() public constant returns (uint);
    function balanceOf(address tokenOwner) public constant returns (uint balance);
    function allowance(address tokenOwner, address spender) public constant returns (uint remaining);
    function transfer(address to, uint tokens) public returns (bool success);
    function approve(address spender, uint tokens) public returns (bool success);
    function transferFrom(address from, address to, uint tokens) public returns (bool success);

    event Transfer(address indexed from, address indexed to, uint tokens);
    event Approval(address indexed tokenOwner, address indexed spender, uint tokens);
}

简单说明一下：
name ： 代币名称
symbol： 代币符号
decimals： 代币小数点位数，代币的最小单位， 18表示我们可以拥有 .0000000000000000001单位个代币。
totalSupply() : 发行代币总量。
balanceOf(): 查看对应账号的代币余额。
transfer(): 实现代币交易，用于给用户发送代币（从我们的账户里）。
transferFrom(): 实现代币用户之间的交易。
allowance(): 控制代币的交易，如可交易账号及资产。
approve(): 允许用户可花费的代币数。

基本介绍完毕，现在你的电脑上至少有chrome,火狐或者opera浏览器中的一个，然后在以上浏览器中安装 MetaMask插件

这样我们就可以在任何系统和平台上进行以太坊的开发了

其他那些怎么注册怎么收好助记词你们这么聪明，肯定懂。我猜你们不会直接用真以太坊代币进行合约部署，所以我们先在以太坊官方给的测试以太坊中部署合约，上图的Rinkeby测试网络，然后点击BUY进入免费获取测试以太坊的界面

不过这里要免费获取测试以太坊的方法比较奇怪，有三种，不过都是把你的以太坊钱包地址复制到推特或者脸谱或者google+中发布，然后在把带有你以太坊钱包地址的消息的链接复制到Rinkeby的输入框中，如果复制链接后网页没有变化，那就刷新一下页面，然后就会看到funded的变化了，上图就是我在推特发的钱包地址复制到Rinkeby获取测试以太坊。

当你获取到测试以太坊后，我们就可以进行代币开发了。我们在 Remix Solidity IDE上开发， Remix Solidity IDE同样，是一个网页开发非常方便， Remix Solidity IDE开发界面是这样的：

关于发代币的代码，直接复制一下代码即可：

pragma solidity ^0.4.16;
interface tokenRecipient { function receiveApproval(address _from, uint256 _value, address _token, bytes _extraData) public; }

contract TokenERC20 {
    string public name;
    string public symbol;
    uint8 public decimals = 18;  // 18 是建议的默认值
    uint256 public totalSupply;

    mapping (address => uint256) public balanceOf;  // 
    mapping (address => mapping (address => uint256)) public allowance;

    event Transfer(address indexed from, address indexed to, uint256 value);

    event Burn(address indexed from, uint256 value);


    function TokenERC20(uint256 initialSupply, string tokenName, string tokenSymbol) public {
        totalSupply = initialSupply * 10 ** uint256(decimals);
        balanceOf[msg.sender] = totalSupply;
        name = tokenName;
        symbol = tokenSymbol;
    }


    function _transfer(address _from, address _to, uint _value) internal {
        require(_to != 0x0);
        require(balanceOf[_from] >= _value);
        require(balanceOf[_to] + _value > balanceOf[_to]);
        uint previousBalances = balanceOf[_from] + balanceOf[_to];
        balanceOf[_from] -= _value;
        balanceOf[_to] += _value;
        Transfer(_from, _to, _value);
        assert(balanceOf[_from] + balanceOf[_to] == previousBalances);
    }

    function transfer(address _to, uint256 _value) public {
        _transfer(msg.sender, _to, _value);
    }

    function transferFrom(address _from, address _to, uint256 _value) public returns (bool success) {
        require(_value <= allowance[_from][msg.sender]);     // Check allowance
        allowance[_from][msg.sender] -= _value;
        _transfer(_from, _to, _value);
        return true;
    }

    function approve(address _spender, uint256 _value) public
        returns (bool success) {
        allowance[msg.sender][_spender] = _value;
        return true;
    }

    function approveAndCall(address _spender, uint256 _value, bytes _extraData) public returns (bool success) {
        tokenRecipient spender = tokenRecipient(_spender);
        if (approve(_spender, _value)) {
            spender.receiveApproval(msg.sender, _value, this, _extraData);
            return true;
        }
    }

    function burn(uint256 _value) public returns (bool success) {
        require(balanceOf[msg.sender] >= _value);
        balanceOf[msg.sender] -= _value;
        totalSupply -= _value;
        Burn(msg.sender, _value);
        return true;
    }

    function burnFrom(address _from, uint256 _value) public returns (bool success) {
        require(balanceOf[_from] >= _value);
        require(_value <= allowance[_from][msg.sender]);
        balanceOf[_from] -= _value;
        allowance[_from][msg.sender] -= _value;
        totalSupply -= _value;
        Burn(_from, _value);
        return true;
    }
}

然后点击右边的RUN，进行设置：

在TokenERC20下面的那一行，第一个数字是代币的数量，第二个字符是代币的名称，第三个字符是代币的符号。上面的Account是你以太坊的钱包地址，Environment选择Rinkeby。然后create一下就怀孕，啊不，是发币了。

然后选submit提交即可。

提交后，点开 Metamask界面，切换到TOKENS，点添加合约，出现如下对话框：

输入合约地址，代币符号和代币小数点后面的位数，默认18，填18就好。

最后成功发布了你自己的代币：

想和我扯淡的朋友欢迎来我公众号吐槽：