如果不思考，单纯地做做试验，此次实验很简单，但这几句简简单单的代码却包括了底层的机制：如参数是如何传递的，堆栈是如何增长的，各个寄存器的作用又是怎样的。
实验截图如下，不是很复杂。
删除指导汇编器和链接器的命令（即是那些以.开头的），得到真正对我们分析汇编代码有用的这一部分。
汇编代码：
g:
pushl %ebp
movl %esp, %ebp
movl 8(%ebp), %eax
addl $3, %eax
popl %ebp
ret
f:
pushl %ebp
movl %esp, %ebp
subl $4, %esp
movl 8(%ebp), %eax
movl %eax, (%esp)
call g
leave
ret
main:
pushl %ebp
movl %esp, %ebp
subl $4, %esp
movl $8, (%esp)
call f
addl $1, %eax
leave
ret
C语言代码：
int g(int x)
{
return x + 3;
}
int f(int x)
{
return g(x);
}
int main(void)
{
return f(8) + 1;
}
这个程序中有3层调用，main函数调用f(),f()调用g(),
main函数运行。
程序是这样运行的，每个函数都有属于自己的堆栈，这一段堆栈叫做栈帧，在32位机上由ebp（帧指针）和esp（栈指针）来划定范围。
main函数执行的时候，先把自己ebp的值保存下来，然后，再将ebp赋值为esp，这样便开始了一个新的栈帧，此时ebp和esp指向了同一处，而这个内存单元里面保存的是ebp的值，esp便开始了对栈帧大小的修改。
为什么要保存ebp的值呢，在函数运行的过程中，ebp一般是不会被修改的，当然，除了下面这两句：
pushl %ebp
movl %esp, %ebp
这两句汇编代码巧妙地只用了一个ebp寄存器就成功地区分开两个函数的栈帧，因为它保存着上一个函数的esp的值，ebp的位置又固定不变。
之前讲过，为了区分开每个函数的栈帧，需要保存ebp和esp，因为在每个函数的执行过程中，想获取当前栈帧的数据，而esp又是变化的，无法把esp当作可靠的参考，此时之前保存的ebp就派上了用场，因为ebp恒定指向此栈帧的最开始。
更为有意思的是以ebp作为参考这种机制在32位机中参数的传递有着重要的意义，接下来在g()函数执行的过程中，就可以看到这样设计的妙处
接下来的
subl $4, %esp
movl $8, (%esp)
是为调用f()准备好参数，参数的压栈顺序是从右向左压栈，分别是参数n，参数n-1,直到参数1。本次只有一个参数，故只保存了立即数8到栈中。
有一点是需要记住的，只有32位系统才有栈帧的概念，并且只能通过栈来传递参数，而64位机则是主要通过寄存器传参，只有当寄存器不够用才使用栈，这样带来的好处就是效率更高。
调用f()函数call f肯定会做一件事情，即将返回地址addl $1, %eax指令的地址压栈。f()函数运行的时候，同样的道理，保存当前的ebp值，设定ebp的指向。
subl $4, %esp，为压栈做准备。
movl 8(%ebp), %eax
movl %eax, (%esp)```
则是通过对ebp的带偏移量的寄存器间接寻址（***基址+偏移量***）找到main函数保存的参数值。因为堆栈是向下增长，那么ebp+4,指向的是上个函数的ret地址，ebp+8则指向的是我们保存的参数8。`movl 8(%ebp), %eax`将8保存到自己的堆栈中去。然后调用g()函数。
***不过我觉得如果使用GCC汇编的时候，优化等级调高，那么，完全没必要浪费这2条指令，因为本身f()函数什么都没做，只是负责传递参数给g()而已，那么直接利用g()的ebp便可寻址到传入的参数。***
*其实，可能直接把g()函数给优化掉了吧？*
g()函数中的形成栈帧的前两句不再多解释，`movl 8(%ebp), %eax`是把传入的参数8存储到eax中，接下来的`addl $3, %eax`则把3加到eax中，`popl %ebp`则是恢复上个函数的ebp，为ret做准备。
`ret`又做了什么呢？`ret`相当于`pop %eip`，恢复eip的值，即调用者的下一条语句。在这个代码中，eip被赋值为f()函数中leave指令的地址，同时由eax返回结果11。
接下来到了f()中的`leave`,也就相当于
movl %ebp，%esp
popl %ebp
第一条把ebp的值赋值给esp，原因在于在当前的栈帧中ebp保存的是当前栈帧的esp值（还记得`movl %esp, %ebp`吗？），esp指向的地方实际保存着ebp，`popl %ebp`则把保存的ebp弹出来（`pushl %ebp`），然后ret指令弹出eip，返回eax到main函数。
main函数中，把1加到eax上，重复同样的动作，整个程序结束。
最后的结构大概是这样：
至于说GCC坚持的x86编程指导防止，也就是说一个函数使用的所有栈空间必须是16字节的整数倍（包括保存的%ebp值的4个字节和返回值的4个字节），在这个代码中并未体现出来，不知道是不是因为GCC比较新的缘故。