Day 16 2019.01.25
查找函数（Vlookup、Hlookup、Index、Match）
日期函数（Year、Month、Datedif）
今天的竖屏终于做出来，也用PPT制作了一个视频，因时间关系没录旁白，有时间再修正啦～
（一）查找函数（Vlookup、Hlookup、Index、Match）
一、基本用法
=VLOOKUP(D2,$A$2:$B$12,2,0)
参数解释：
=VLOOKUP(要查找的销售员,包含销售员和其销售额的数据源区域,找到后返回第2列,精确查找)
第一参数：找什么（或者说按什么查找），按销售员查找，所以输入D2
第二参数：在哪找，数据源区域在A:B列，所以输入$A$2:$B$12
第三参数：找到后返回第几列，我们要查找的是销售额，销售额位于B列，即第二参数中的第二列，所以输入2
第四参数：这里要精确查找，所以输入0
参数解释：
=HLOOKUP(G2,$A$1:$E$9,6,0)
=HLOOKUP(要查找的月份,包含销售员和其月份的数据源区域,找到后返回第6行,精确查找)
第一参数：找什么（或者说按什么查找），按月份查找，所以输入G2
第二参数：在哪找，数据源区域在A:E列，所以输入$A$1:$E$9
第三参数：找到后返回第几行，我们要查找的是独孤求败，位于第6行，即第二参数中的第6行，所以输入6
第四参数：这里要精确查找，所以输入0
MATCH函数
作用:在一个区域或数组中查找指定数值的位置，如果查找不到则返回错误值
=MATCH(A13,$A$2:$A$8,0)
第一参数：查找的值
第二参数：查找的区域or数组
第三参数：0和FALSE表示精确，1和TRUE表示模糊
INDEX函数
作用：根据指定的行数和列数，返回指定区域的值。
① =INDEX($A$2:$A$8,B14)
第一参数：指定的区域
第二参数：数值所在的位置
② =INDEX($A$2:$C$8,4,2)
第一参数：指定的区域
第二参数：行数
第三参数：列数
③ =INDEX($A$2:$A$8,MATCH(A36,$B$2:$B$8,0))
综合运用
作用：反向查询
利用Match函数查找位置（$B$2:$B$8）
二、借助名称框查找
=VLOOKUP(D2,查找区域,2,0)
注意：利用名称框抓取数据区域，就不用在手工去选择区域
三、通配符模糊查找
=VLOOKUP("*老师*",$A$2:$B$12,2,0)
说明：
通配符星号*通配任意个字符
问号?通配单一字符
四、查找返回多列数据
=COLUMN() 例：G列 =COLUMN() 结果是 7
=COLUMN(B1) 例：结果是 2
=VLOOKUP($G2,$A$2:$E$9,COLUMN(B1),0)
要求：
左侧表格是数据源区域，需要在右侧区域根据姓名调取对应的数据
操作步骤：
选中H2:K5单元格区域，输入以下公式=VLOOKUP($G2,$A$2:$E$9,COLUMN(B1),0)后按
五、查找指定区域
=VLOOKUP($G2,$A$2:$E$9,MATCH($H$1,$A$1:$E$1,0),0)
要求：
左侧表格是数据源区域，需要在右侧区域根据姓名调取对应的数据，黄色区域是需要填写公式的区域。
六、多条件查找（一对多查找）
① 需要借助辅助列 =C2&COUNTIF($C$2:C2,C2) 设产品序列
② 依据产品序列查找
=IFERROR(VLOOKUP($F$2&ROW(A1),$A$2:$D$15,COLUMN(B1),0),"")
说明：
=ROW(F1) 例：结果是 1
=COLUMN(B2) 例：结果是 2
操作步骤：
步骤1 在左表前插入一列并设置公式，用countif函数统计客户的销售额并用&连接成 产品名称+序号的形式。=C2&COUNTIF($C$2:C2,C2)
步骤2 在F9设置公式并复制即可得到F2单元格中产品的所有销售记录。
=IFERROR(VLOOKUP($F$2&ROW(A1),$A:$D,COLUMN(B1),0),"")
解决一对多查找的关键点是把重复的值用Countif变成不同的，然后用Vlookup函数再进行查找
七、区间查找
=VLOOKUP(B2,$I$2:$J$5,2)
要求: 需要按照等级划分规则，将成绩划分到其对应的等级中。
说明:
=IF(B2>=90,"A",IF(B2>=80,"B",IF(B2>=60,"C","D")))
=IF(B2<60,"D",IF(B2<80,"C",IF(B2<90,"B","A")))
注意:
必须是升序排列
八、动态图表
=C9&" 销售额" 要查找的内容
=VLOOKUP($C$9,$A$2:$G$7,COLUMN(),0) 用vlookup查找一整行数值，即可
（二） 日期函数（Year、Month、Datedif）
一、基本用法
=TODAY() 2019/1/25 当天日期
=NOW() 2019/1/25 16:31 现在日期和时间
=YEAR(D6) 2019 取得年份
=MONTH(D6) 1 取得月份
=DAY(D6) 25 取得天数
=HOUR(D7) 16 取得小时数
=MINUTE(D7) 31 取得分钟数
=SECOND(D7) 7 取得秒数
=TIME(B7,B8,B9) 16:31:07 根据小时数分钟和秒数组合成时间
=DATE(2017,12,6) 2017/12/6 根据年月日数组合成日期
=WEEKDAY(D7,1) 5 一周中的第几天，第二个参数是从哪一天开始算起
二、计算出生日期
出生年 =MID(B2,7,4)
出生月 =MID(B2,11,2)
出生日 =MID(B2,13,2)
出生日期 =DATE(C2,D2,E2)
年龄 =YEAR(TODAY())-C2
三、销售明细分析
年 =YEAR(D2)&"年"
月 =MONTH(D2)&"月"
日 =DAY(D2)&"日"
四、基本用法-Datedif
计算年数 29 =DATEDIF(C2,D2,"y") y 返回整年数
计算月份 348 =DATEDIF(C2,D2,"m") m 返回整月数
计算天数 10616 =DATEDIF(C7,D7,"d") d 返回整天数
忽略年计算月数 0 =DATEDIF(C2,D2,"ym") ym 返回参数1和参数2的月数之差，忽略年和日
忽略年计算天数 24 =DATEDIF(C2,D2,"yd") yd 返回参数1和参数2的天数之差，忽略年。按照月、日计算天数
忽略月计算天数 24 =DATEDIF(C2,D2,"md") md 返回参数1和参数2的天数之差，忽略年和月
函数解释：DATEDIF(起始日期,终止日期,间隔单位)
计算2个日期的间隔
五、计算工龄
间隔年份 9 9年 =DATEDIF(C2,D2,"y")
间隔月份 0 0月 =DATEDIF(C2,D2,"ym")
间隔天数 24 24日 =DATEDIF(C2,D2,"md")
=DATEDIF(C2,D2,"y")&"年"&DATEDIF(C2,D2,"ym")&"月"&DATEDIF(C2,D2,"md")&"日"
六、生日提醒
=365-DATEDIF(C3,TODAY(),"yd")
七、身份证号码计算年龄
=DATEDIF(TEXT(MID(B2,7,8),"0-00-00"),TODAY(),"y")
