使用systemtap调试软件技巧

技巧一

获取函数运行时间。编写协议类的软件，很多问题往往和某个函数体的运行时间有关，获取耗时长的函数，往往是解决问题的关键。如何用systemtap快速定位问题函数？

#!/usr/bin/env stap

probe process("target_solftware").function("target_function").call {
    printf("%s << %s\n", thread_indent(1), ppfunc());
}

probe process("target_solftware").function("target_function").return {
    printf("%s >> %s\n", thread_indent(-1), ppfunc());
}

获取的打印如下：

  5027 gkappsession(9364): >>cpy_frame 
     0 gkappsession(9364): <>cpy_frame 
     0 gkappsession(9364): <>cpy_frame 
     0 gkappsession(9364): <>cpy_frame 
     0 gkappsession(9364): <>cpy_frame 

第一行是函数运行时间，单位为us。这个是获取整个函数的调用时间，如果这个函数里面又调用了其他的函数，如何确定调用的函数中，哪个耗时比较多呢？

#!/usr/bin/env stap

global switcher

probe begin {
    switcher = 0
}

probe process("target_solftware").library("target_library").function("target_function").call {
    switcher = 1
}

probe process("target_solftware").library("target_library").function("target_function").return {
    switcher = 0
    printf("%s >>%s\n", thread_indent(-1), ppfunc())
}

probe process("target_solftware").library("target_library").function("*").call {
    if (switcher == 1) {
        printf("%s <<%s\n", thread_indent(1), ppfunc())
    }
}

probe process("target_solftware").library("target_library").function("*").return {
    if (switcher == 1 ) {
        printf("%s >>%s\n", thread_indent(-1), ppfunc())
    }
}

这个脚本可以具体到函数里面的子函数的调用时间。可以快速定位到问题函数。

技巧二

获取帧率，协议类软件性能的体现就是帧率。数据包的发送频率越高，终端体验越好。如何快速查看某个函数的调用帧率：

#!/usr/bin/env stap

global rate2
global rate1
global rate3
probe process("/usr/bin/idv-channel").library("libgkapp.so.1").function("gkapp_enc_engine_encode_frame") {
        rate3 ++
}

probe process("/usr/bin/gkappsession").library("libgkapp.so.1").function("encode_handle_worker") {
        rate2 ++
}
probe process("/usr/bin/gkappsession").library("libgkapp.so.1").function("do_grab_data") {
       rate1 ++
}

probe timer.s(1) {
        printf("%d, %d, %d\n",  rate1, rate2, rate3);
        rate1 = 0;
        rate2 = 0;
        rate3 = 0;

}