Unity Shader渐变纹理总结

概述

渐变纹理多用于卡通风格的渲染。渐变纹理可以控制色调渐变，达到色调变化的效果。这种方法形成的轮廓线比传统漫反射更明显。我们这里使用的渐变纹理是二维纹理，记录了色调的渐变。不同的渐变纹理提供了不同的色调渐变方案，能形成不同的美术风格。

代码详解

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Unity Shaders Book/Chapter 7/Ramp Texture"{
    Properties{
        _Color ("Color Tint",Color)=(1,1,1,1)
        _RampTex ("Ramp Tex",2D)="white" {}
        _Specular ("Specular",Color)=(1,1,1,1)
        _Gloss ("Gloss",Range(8.0,256))=20
    }
    SubShader{
        pass{
            Tags{"LightMode"="ForwardBase"}

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            fixed4 _Color;
            sampler2D _RampTex;
            float4 _RampTex_ST;
            fixed4 _Specular;
            float _Gloss;

            struct a2v{
                float4 vertex:POSITION;
                float3 normal:NORMAL;
                float4 texcoord:TEXCOORD0;
            };

            struct v2f{
                float4 pos:SV_POSITION;
                float3 worldNormal:NORMAL;
                float3 worldPos:TEXCOORD1;
                float2 uv:TEXCOORD2;
            };

            v2f vert(a2v v){
                v2f o;
                o.pos=UnityObjectToClipPos(v.vertex);

                o.worldNormal=UnityObjectToWorldNormal(v.normal);

                o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;

                o.uv=v.texcoord.xy*_RampTex_ST.xy+_RampTex_ST.zw;

                return o;
            }

            fixed4 frag(v2f i):SV_TARGET{
                fixed3 worldNormal=normalize(i.worldNormal);
                fixed3 worldLightDir=UnityWorldSpaceLightDir(i.worldPos);
                fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;

                fixed halfLambert=0.5*dot(worldNormal,worldLightDir)+0.5;
                //fixed3 diffuseColor=((tex2D(_RampTex,fixed2(halfLambert,halfLambert)).rgb+tex2D(_RampTex,i.uv).rgb)/2)*_Color.rgb;
                fixed3 diffuseColor=tex2D(_RampTex,fixed2(halfLambert,halfLambert)).rgb*_Color.rgb;
                fixed3 diffuse=_LightColor0.rgb*diffuseColor;

                fixed3 viewDir=normalize(UnityWorldSpaceViewDir(i.worldPos));
                fixed3 halfDir=normalize(viewDir+worldLightDir);
                fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(max(0,dot(worldNormal,halfDir)),_Gloss);

                return fixed4(ambient+diffuse+specular,1.0);
            }
            ENDCG
        }
    }
    Fallback "Specular"
}

这段代码只有一个地方需要特别注意，其他地方与之前并没有太大差别：
fixed3 diffuseColor=tex2D(_RampTex,fixed2(halfLambert,halfLambert)).rgb*_Color.rgb;
这行代码是对渐变纹理进行采样。
我们使用的渐变纹理如下：



我们可以发现，所有的渐变纹理实质上是一个一维纹理，只在水平方向有变化。所以在采样的时候使用半兰伯特参数halfLambert来进行采样，这样的话，色调的渐变和漫反射挂上了钩。
最终效果如下：

注意，由于Wrap Mode设置的问题，在某些模型表面，由于浮点数精度的问题，虽然halfLambert最大值为1，但可能出现1.0001这样的值，此时，Wrap Mode会导致完全不同的采样结果(渐变纹理两端的颜色差别很大)，所以会产生瑕疵。这种情况一般是由于Repeat模式导致的，如图：

此时我们只要改为Clamp就可以了。