windows系统，使用命令行修改当前用户密码以及修改远程桌面端口并添加防火墙入站规则

在工作中，有好多台服务器的密码是一样的，当时间比较久以后，为了安全起见想要把全部的密码修改掉，修改后的密码恰好也是一样的，那么可以利用bat脚本完成这项工作：

@echo off
title 重置当前用户密码

:cx
echo 当前用户名为：%username%

echo -----------------------------
echo 开始修改密码操作
echo -----------------------------

net user Administrator test@1234

echo.
echo.
echo 密码重置成功,密码为test@1234 请按任意键关闭!!! & pause>nul

在工作中还会为了安全，修改服务器默认的远程桌面端口，并且添加防火墙的入站规则，如果服务器比较多，也可以使用bat脚本完成这项工作：

@ECHO OFF
ECHO   =====================  Step 01   ==============================
ECHO 1-1 查询需要修改的远程桌面端口号，默认为16进制显示
 
REG QUERY "HKLM\SYSTEM\CURRENTCONTROLSET\CONTROL\TERMINAL SERVER\WDS\RDPWD\TDS\TCP" /V "PORTNUMBER"
 
REG QUERY "HKLM\SYSTEM\CURRENTCONTROLSET\CONTROL\TERMINAL SERVER\WINSTATIONS\RDP-TCP" /V "PORTNUMBER"
 
REM 1-2 修改上述两个端口
 
REM 设置新的端口号到变量NEWPORTNUMBER中，以10进制表示
SET NEWPORTNUMBER=2346
REG ADD "HKLM\SYSTEM\CURRENTCONTROLSET\CONTROL\TERMINAL SERVER\WDS\RDPWD\TDS\TCP" /V "PORTNUMBER" /T REG_DWORD /D %NEWPORTNUMBER% /F
 
REG ADD "HKLM\SYSTEM\CURRENTCONTROLSET\CONTROL\TERMINAL SERVER\WINSTATIONS\RDP-TCP" /V "PORTNUMBER" /T REG_DWORD /D %NEWPORTNUMBER% /F
 
ECHO 1-3 再次查询修改后的远程桌面端口号，看属否修改成功，默认为16进制显示
 
REG QUERY "HKLM\SYSTEM\CURRENTCONTROLSET\CONTROL\TERMINAL SERVER\WDS\RDPWD\TDS\TCP" /V "PORTNUMBER"
 
REG QUERY "HKLM\SYSTEM\CURRENTCONTROLSET\CONTROL\TERMINAL SERVER\WINSTATIONS\RDP-TCP" /V "PORTNUMBER"
 
ECHO   =====================  Step 02   ==============================
ECHO 重启远程桌面有关的服务
 
ECHO 先停止
NET STOP "REMOTE DESKTOP SERVICES" /Y
 
ECHO 再重启
NET START "REMOTE DESKTOP SERVICES"
 
ECHO   =====================  Step 03   ==============================
ECHO 打开远程桌面功能
 
REG ADD "HKLM\SYSTEM\CURRENTCONTROLSET\CONTROL\TERMINAL SERVER" /V "fDENYTSCONNECTIONS" /T REG_DWORD /D 00000000 /F
 
ECHO 查询修改后的状态
 
REG QUERY "HKLM\SYSTEM\CURRENTCONTROLSET\CONTROL\TERMINAL SERVER" /V "fDENYTSCONNECTIONS"

echo ---------------------------------------------------------------------------------------
echo 添加防火墙规则
netsh advfirewall firewall add rule name="2346p" protocol=TCP dir=in localport=2346 action=allow

echo ---------------------------------- & pause>nul

在这个脚本中写死了需要修改的远程端口号，可以根据需要修改；还有防火墙入站规则的名称和端口也可以自己修改

以上两个脚本都需要以管理员模式运行