[068][汇编语言]实验14 编程 以“年/月/日 时:分:秒” 的格式，显示当前的日期和时间

实验14 ： 编程 以“年/月/日 时:分:秒” 的格式，显示当前的日期和时间

实际运行

实验14 编程 以年月日 时分秒 的格式，显示当前的日期和时间

完整源码

assume cs:code
code segment
    date: db 9,8,7,4,2,0
    blank: db '// ::'
    start:      mov ax,cs
                mov ds,ax
                
                mov bx,0B800H
                mov es,bx
                mov bl,02H
                mov di,160*12+40*2
                mov si,offset date
                mov cx,6
    showdate:   push cx
                mov al,[si]
                out 70H,al
                in al,71H
                
                mov ah,al
                mov cl,4
                shr ah,cl
                and al,00001111B
                
                add ah,30H
                add al,30H
                
                mov byte ptr es:[di],ah
                mov byte ptr es:[di+1],bl
                mov byte ptr es:[di+2],al
                mov byte ptr es:[di+3],bl

            
                add di,6
                inc si
                pop cx
                loop showdate
    
                mov di,160*12+40*2
                mov si,offset blank
                mov cx,5
    showblank:  push cx
                
                mov al,[si]
                mov byte ptr es:[di+4],al
                mov byte ptr es:[di+5],bl
                
                add di,6
                inc si
                pop cx
                loop showblank
                
            mov ax,4c00h
            int 21H
            
    code ends
    end start

代码参考

• 实验13 第（3）题 用 [si] 访问变量数据的思想
  https://www.jianshu.com/p/a801c7dfd36b
• 左移指令 与 右移指令
  https://www.jianshu.com/p/e055a9c824ba
• BCD 码（8421码）
  https://www.jianshu.com/p/e2c4943eb945

代码说明

• 使用 [si] 来依次访问代表 年 月 日 时 分 秒的端口号

date: db 9,8,7,4,2,0
mov si,offset date
mov al,[si]
inc si
依次访问得到 9 8 7 4 2 0

CMOS RAM 中的规定：
端口号 9   8     7   4   2     0
意义  年   月   日   时   分   秒

因此，本轮循环次数为 六次
mov cx,6

• 年/月/日 时:分:秒，18/05/04 16:39:47

以 15 举例，说明屏幕上最终怎么显示出 15 ：

屏幕上要显示出 15
本质上是要显示出 1 然后再显示出 5

往回退一步
  要送入 显存 的ASCII码，1 对应 31H  、 5 对应 35H

  再往回退一步
      1 对应的二进制是 0000 0001H、 5 对应的二进制是 0000 0101H
      这时候，刚好用 AH 存 0000 0001H，用 AL 存 0000 0101H
      
  再往回退一步，就知道 AL， AH怎么来的了，
                mov al,[si]
                out 70H,al
                in al,71H
                
                mov ah,al
                mov cl,4
                shr ah,cl
                and al,00001111B
 
实际上，  in al,71H 拿到的 al 是 0001 0101 B
通过指令，
不过是把现在 al 的前四位 0001 放到 ah 里面
然后用 al 专门存 al原来的后四位 0101
但是由于，al、ah 都是8位寄存器，所以需要在前面补上 0000

从   in al,71H 开始 al = 0001 0101B
 mov ah,al  使得 ah = 0001 0101B
 mov cl,4    shr ah,cl 使得 ah = 0000 0001 B（右移的结果）
 and al,00001111B

al   0001 0101 B
and  0000 1111 B
-----------------------
     0000 0101 B

and 运算，用0000 1111 去and，
就是说不要前四位、只要后四位

最终 
AH = 0000 0001 B = 01 H
AL =  0000 0101 B = 05 H

• BCD码（8421码）：BCD码值+30H = 十进制数对应的ASCII码

  add ah,30H
  add al,30H

AH =31H （显示在屏幕上就是 数值 1）
AL = 35H （显示在屏幕上就是 数值 5）

• 间隔符号也是遍历依次取

 blank: db '// ::'
 mov si,offset blank
 mov al,[si]

五个符号，分别放在 年 月 日 时 分 后面

另一种写法：间隔用 db '00/00/00 00:00:00$' 搭配 DOS int 21H 中断，预先填好间隔符

 blank: db '00/00/00 00:00:00$'
    start:      mov ah,2
                mov bh,0
                mov dh,12
                mov dl,40
                int 10H
                
                mov ax,cs
                mov ds,ax
                mov dx,offset blank
                mov ah,9
                int 21h

使用DOS 的 int 21H 中断，9号中断程序 ，功能是显示字符串，遇到$终止
这样可以预先一次性把所有的间隔符都填好

• DOS int 21H 9号中断程序 应用 参考
  https://www.jianshu.com/p/b0b649c207dd
• 受到启发 db '00/00/00 00:00:00$'
  https://blog.csdn.net/wyf12138/article/details/53914262

实际运行

实验14 另一种写法：间隔用 `db '00/00/00 00:00:00$'` 搭配 **DOS int 21H** 中断，预先填好间隔符

完整源码

assume cs:code
code segment
    date: db 9,8,7,4,2,0
    blank: db '00/00/00 00:00:00$'
    start:      mov ah,2
                mov bh,0
                mov dh,12
                mov dl,40
                int 10H
                
                mov ax,cs
                mov ds,ax
                mov dx,offset blank
                mov ah,9
                int 21h

                mov bx,0B800H
                mov es,bx
                mov bl,02H
                mov di,160*12+40*2
                mov si,offset date
                mov cx,6
    showdate:   push cx
                mov al,[si]
                out 70H,al
                in al,71H
                
                mov ah,al
                mov cl,4
                shr ah,cl
                and al,00001111B
                
                add ah,30H
                add al,30H
                
                mov byte ptr es:[di],ah
                mov byte ptr es:[di+1],bl
                mov byte ptr es:[di+2],al
                mov byte ptr es:[di+3],bl

            
                add di,6
                inc si
                pop cx
                loop showdate
 
            mov ax,4c00h
            int 21H
            
    code ends
    end start