原文链接：https://markhneedham.com/blog/2018/11/05/neo4j-inferred-relationships-apoc-triggers/
对图数据库进行建模时，我非常看中的一点是：其在进行关系推导时要比其他关系型数据库更简单。本文我们将学习怎样使用APOC的触发器特性来进行关系推导的计算与保存。
聚会图模型
在开始介绍之前，我们先来了解一下什么是推导关系。首先我们先创建一个小型的图模型，包含有Person、Meetup和Topic三类节点。可使用下面语句进行创建：
MERGE (mark:Person {name: "Mark"})
MERGE (neo4jMeetup:Meetup {name: "Neo4j London Meetup"})
MERGE (bigDataMeetup:Meetup {name: "Big Data Meetup"})
MERGE (dataScienceMeetup:Meetup {name: "Data Science Meetup"})
MERGE (dataScience:Topic {name: "Data Science"})
MERGE (databases:Topic {name: "Databases"})
MERGE (neo4jMeetup)-[:HAS_TOPIC]->(dataScience)
MERGE (neo4jMeetup)-[:HAS_TOPIC]->(databases)
MERGE (bigDataMeetup)-[:HAS_TOPIC]->(dataScience)
MERGE (bigDataMeetup)-[:HAS_TOPIC]->(databases)
MERGE (dataScienceMeetup)-[:HAS_TOPIC]->(dataScience)
MERGE (dataScienceMeetup)-[:HAS_TOPIC]->(databases)
MERGE (mark)-[:MEMBER_OF]->(neo4jMeetup)
MERGE (mark)-[:MEMBER_OF]->(bigDataMeetup)在Neo4j浏览器看到图的是这样：
寻找潜在关系
现在在Person和Topic节点之间是没有关系的，换句话说，我们不知道哪个人对哪个主题有兴趣。然而，我们发现通过Meetup节点有一个间接的关系。
译者言：上图作者画错了，应该把Group换成Meetup才对。
我们假设一个人参加了多次聚会，其中有3次聚会都有这个主题，我们就可以推断出他对这个主题感兴趣。换句话说，只要某人参加了有这主题的聚会3次或3次以上，我们就会在Person和Topic节点间建立INTERESTED_IN关系。Cypher语句如下：
MATCH (start:Person {name: "Mark"})-[:MEMBER_OF]->()-[:HAS_TOPIC]->(topic)
WHERE not((start)-[:INTERESTED_IN]->(topic))
WITH start, topic, count(*) AS count
WHERE count >= 3
MERGE (start)-[interestedIn:INTERESTED_IN]->(topic)
SET interestedIn.tentative = true因为Mark参加带有任一主题的聚会都不到3次，所以，上面的Cypher语句并不会创建INTERESTED_IN关系。我们现在修改一下数据，让Mark再参加一次Data Science聚会，修改语句如下：
MATCH (p:Person {name: "Mark"})
MATCH (meetup:Meetup {name: "Data Science Meetup"})
MERGE (p)-[:MEMBER_OF]->(meetup)上面语句运行后，再执行之前的Cypher语句，此时有下面的输出：
Created 2 relationships, completed after 2 ms.很好，此时我们已经知道Mark对DataScience和Database这两个主题都感兴趣。
我们把tentative属性设置在true，表示这是一个推导关系。后续可以考虑让用户确认这个关系的正确性。
触发器
这个关系建立起来了，但是过程太痛苦了。每次建立一个新的MEMBER_OF关系后，就要运行那条推导关系查询的语句，这个过程能自动化就好了。
别说，还真行。使用APOC库中的触发器就可以让这个过程自动化。在APOC库中，对触发器是这么描述的
在触发器中注册一段可以被调用的Cypher查询语句，当Neo4j中的数据发生变化时，这段Cypher语句将会在数据的提交前或提交后被运行起来。 好，接下来我们建立一个触发器，每当一个新关系被建立时就运行这段脚本。代码如下：
CALL apoc.trigger.add("interests",
"UNWIND [rel in $createdRelationships WHERE type(rel) = 'MEMBER_OF'] AS rel
WITH startNode(rel) AS start, endNode(rel) AS end
MATCH (start)-[:MEMBER_OF]->()-[:HAS_TOPIC]->(topic)
WHERE not((start)-[:INTERESTED_IN]->(topic))
WITH start, topic, count(*) AS count
WHERE count >= 3
MERGE (start)-[interestedIn:INTERESTED_IN]->(topic)
SET interestedIn.tentative = true
",
{phase:'before'})上面这段代码是基于这样一个假设：在每个事务中，每个Person只会创建一条MEMBER_OF关系。我们的触发器将会接收到一个事务中所有创建关系，然后只取出MEMBER_OF关系，接着运行我们的Cypher语句，在Person和Topic之间建立INTERESTED_IN关系，表示此人对这个主题感兴趣。
如果你认为参加3次这种主题的聚会太少了，想改变这个阈值，仅需要改变上面查询语句中的这行代码就可以：
WHERE count >= 3好，关于APOC中的触发器先介绍到这里，希望对你有用。