上一篇文章SAS如何生成箱型图（Box-Plot） 1简单介绍了箱型图（Box-Plot）的概念，这一篇文章来具体介绍SAS中生成箱型图的方法。示例代码的数据，使用SASHELP逻辑库中的Class数据集。
1. Boxplot过程步
针对箱型图，SAS有专门的过程步 ——Proc Boxplot 来实现。
我们来看一下其语法，Boxplot步的主体部分是PLOT语句，组成部分是分析变量（analysis-variable）和分组变量（group-variable）。这里要注意，PLOT语句要求分析变量和分组变量必须都存在。如果分组变量缺失，SAS运行会出现Error。同时，在进行Proc Boxplot之前，分析数据集必须要按照分组变量排序，否则会出现意想不到的结果，具体看下面示例。
ods graphics off;
title 'Box Plot for Class Height without Sorting Sex';
proc boxplot data = sashelp.class;
plot Height * sex;
run;
经过排序后，箱型图如下图，这也是日常分析中想要的结果。
ods graphics off;
title 'Box Plot for Class Height with Sorting Sex';
proc sort data = sashelp.class out = class;
by sex;
run;
proc boxplot data = class;
plot Height * sex;
run;
关于Boxplot步的其他选项的用法，以及图标的修饰，大家可以参考Boxplot步 SAS 官方文档，这里就不再详细介绍。
2. Sgplot过程步中的VBox、HBox语句
SAS中Sgplot过程步可以生成一个或多个图表，并可以让它们在同一个坐标中显示。我们来看一个简单的例子，一个坐标轴中同时画出x轴为身高、y轴为体重的散点图和椭圆图。
***散点图和椭圆图;
proc sgplot data=sashelp.class;
scatter x=height y=weight;
ellipse x=height y=weight;
run;
关于箱型图，Sgplot过程步有两个相关的语句：HBOX和VBOX。只看语句名称，应该可以猜到，HBOX是用来生成水平箱型图；VBOX是用来生成垂直箱型图的。
***HBOX;
proc sgplot data = sashelp.class;
hbox height/group = sex;
run;
***VBOX;
proc sgplot data = sashelp.class;
vbox height/group = sex;
run;
其他选项的用法以及图标的修饰，可以参考SAS® 9.4 ODS Graphics Procedures Guide, Sixth Edition
)
3. Sgpanel过程步中的Vbox、HBox语句
SAS中Sgpanel步可以为**一个或多个分类变量创建图形单元面板 **(a panel or graph cells)。我们直接看示例代码：
***Sgpanel Hbox;
proc sgpanel data = sashelp.class;
panelby sex;
hbox height;
run;
***Sgpanel Vbox;
proc sgpanel data = sashelp.class;
panelby sex;
vbox height;
run;
其他选项的用法以及图标的修饰，可以参考SAS® 9.4 ODS Graphics Procedures Guide, Sixth Edition
4. Template模板的应用
SAS GTL (Graph Template Language)是ODS (Output Delivery System)的扩展，可以用来生成复杂的图形。GTL生成的图形是由模板 (Template)定义生成的，这些模板定义控制图形的格式和外观，并指定要在图形显示中展现的内容。GTL的模板是由PROC TEMPLATE进行定义；GTL的模板是由PROC SGRENDER进行引用。
关于GTL具体语法，可以参考SAS® 9.4 Graph Template Language Reference, Fifth Edition
我来简单介绍下，如何通过GTL模板来来生成箱型图。第一步，建立一个模板（TEMPLATE），模板中保存了作图的变量信息；第二部，调用定义好的作图模板，这一步需要指明作图的数据源以及模板的名称。
***Template definations;
proc template;
define statgraph boxplot;
begingraph;
layout overlay;
boxplot y=height x=sex;
endlayout;
endgraph;
end;
run;
***Render the Template;
proc sgrender data = sashelp.class template=boxplot;
run;
总结：以上简单介绍了SAS中4种生成Boxplot的方法，除了GTL，其他3种方法只需一个过程步就可以完成。不过，在临床试验分析中，作图基本都是用GTL实现。我们可以看到，上面示例代码所生成的Boxplot比较简单，只有一些基础内容。如果想要在图形中展现更多的统计内容，简单过程步是很难实现的。而通过GTL的模板定制，可以生成复杂、精美的图形。下一篇文章，将介绍GTL在临床试验中Boxplot的具体应用。
相关文章：
SAS如何生成箱型图(Box-Plot) 1--箱型图简介
SAS如何生成箱型图(Box-Plot) 3--临床试验中具体应用