X86汇编语言：从实模式到保护模式（代码+注释）--c7

X86汇编语言：从实模式到保护模式（代码+注释）–c6

         ;代码清单7-1
         ;文件名：c07_mbr.asm
         ;文件说明：硬盘主引导扇区代码
         ;创建日期：2011-4-13 18:02
         
         jmp near start
	
 message db '1+2+3+...+100='
        
 start:
         mov ax,0x7c0           ;设置数据段的段基地址 
         mov ds,ax

         mov ax,0xb800          ;设置附加段基址到显示缓冲区
         mov es,ax

         ;以下显示字符串 
         mov si,message          
         mov di,0
         mov cx,start-message
     @g:
         mov al,[si]
         mov [es:di],al
         inc di
         mov byte [es:di],0x07
         inc di
         inc si
         loop @g		;inc两次di是因为di指向的是b800位置，每次 需要写入一个字符和一个显示设置字节，因此inc两次

         ;以下计算1到100的和 
         xor ax,ax
         mov cx,1
     @f:
         add ax,cx
         inc cx
         cmp cx,100
         jle @f

         ;以下计算累加和的每个数位 
         xor cx,cx              ;设置堆栈段的段基地址
         mov ss,cx				;目前cx是0，所以ss段寄存器保存的是0x00000
         mov sp,cx				;设置堆栈指针:目前堆栈顶为0000：0000

         mov bx,10				
         xor cx,cx
     @d:
         inc cx					
         xor dx,dx
         div bx
         or dl,0x30            ;转ascii码
         push dx			   ;push操作数可以是16位寄存器（通用寄存器或者段寄存器）或者内存单元地址
							   ;push操作后，由于操作数是dx所以sp需要减2，因此存储完dx内容的地址在（0000：FFFF和0000：FFFE）
         cmp ax,0
         jne @d

         ;以下显示各个数位 
     @a:
         pop dx				   ;直接使用SS:SP地址来弹出数据
         mov [es:di],dl
         inc di
         mov byte [es:di],0x07
         inc di
         loop @a
       
         jmp near $ 
       

times 510-($-$$) db 0
                 db 0x55,0xaa