Arduino U8glib 数字闹钟及温度计（不需时钟模块）

前言

最近想用Arduino制作一个数字闹钟，但因为没有独立的时钟模块造成时间误差太大让我困扰，但还是想了一个办法，让程序自动校正时间，于是不需要时钟模块，时间也能相当准确，效果如下图：

材料

名称	数量
Arduino UNO	一个
LCD 12864显示屏	一个
LM35 热敏电阻	一个
3W小喇叭	一个
面包版	一个
跳线	数根

校正时间的方法

以准确时间为标准，测量一段时间内的误差（比如测量3小时后的误差），计算每秒钟的误差毫秒数，取整后然后每秒进行校正，由于取整，仍然会有误差，再将误差扩大60倍，也就是每分钟的误差，取整后每分钟再进行校正，以此类推，直到你认为精确度足够。

Arduino代码

#include 

#define BUZZER 10//喇叭针脚

U8GLIB_ST7920_128X64_4X u8g(13, 12, 11);//配置屏幕针脚

int base = 0, ms = 0, s = 0, mi = 48, hr = 19, week = 6;//进行初始化时间
int nMi = 0, nHr = 8;//闹钟时间
double tem = 0;//温度

void setup() {
  pinMode(BUZZER, OUTPUT);
  u8g.setRot180();//旋转屏幕180度
  base = millis();//初始化基准时间
}

void loop() {
  calc();//更新时间
  func();//处理函数
  u8g.firstPage(); do draw(); while (u8g.nextPage());//刷新屏幕
}

void func() {
  tem = (double)analogRead(A0) * (5 / 10.23);//读取并计算温度
  if (hr == nHr && mi == nMi) {//播放闹钟1分钟
    tone(BUZZER, 200 + ms);//随毫秒数改变闹钟音调，产生铃声
  } else {
    noTone(BUZZER);//结束播放铃声
    digitalWrite(BUZZER, LOW);//设置为低电平
  }
}

void calc() {
  ms = millis() - base;
  if (ms > 999) {
    ms = 0;
    base = millis() - 61; //用于校正误差,每过1s提前61ms
    if (++s > 59) {
      s = 0;
      base = millis() + 8; //用于校正误差,每过1min延迟8ms
      if (++mi > 59) {
        mi = 0;
        base = millis() - 38; //用于校正误差,每过1hour提前38ms
        if (++hr > 23) {
          hr = 0;
          base = millis() - 8; //用于校正误差,每过1day提前8ms
          if (++week > 6) week = 0;
        }
      }
    }
  }
}

void draw() {
  for (int x = 0; x < 2 * s; x++)//按照秒数绘制宽4个像素的进度条
    for (int y = 0; y < 4; y++)
      u8g.drawPixel(x + 5, y + 3);

  u8g.setFont(u8g_font_gdb30n);//设置gdb30像素数字类字体

  if (hr > 9) {//如果数字只有一位就添加0在前面
    u8g.setPrintPos( 8, 41);
  } else {
    u8g.drawStr(10, 41, "0");
    u8g.setPrintPos( 32, 41);
  }
  u8g.print(hr);

  if (s % 2 == 0)//冒号在秒数为偶数时才绘制，达到冒号闪烁的效果
    u8g.drawStr( 56, 37, ":");

  if (mi > 9) {//如果数字只有一位就添加0在前面
    u8g.setPrintPos( 70, 41);
  } else {
    u8g.drawStr(70, 41, "0");
    u8g.setPrintPos( 94, 41);
  }
  u8g.print(mi);

  u8g.setFont(u8g_font_gdb14r);//设置gdb14像素常用类字体
  switch (week) {//绘制星期数到屏幕
    case 0: u8g.drawStr(6, 61, "Sun"); break;
    case 1: u8g.drawStr(6, 61, "Mon"); break;
    case 2: u8g.drawStr(6, 61, "Tue"); break;
    case 3: u8g.drawStr(6, 61, "Wed"); break;
    case 4: u8g.drawStr(6, 61, "Thu"); break;
    case 5: u8g.drawStr(6, 61, "Fri"); break;
    default: u8g.drawStr(6, 61, "Sat");
  }

  u8g.setPrintPos( 56, 61);//绘制温度示数到屏幕
  u8g.print(tem);
  u8g.drawStr(111, 61, "C");
}

可动态调整时间的Arduino代码

使用一个电位器和一个按钮进行调整时间，电位器选择模式或调整数字，按钮进行选定，具体请从代码中理解。

#include 

#define BUZZER 10//喇叭针脚
#define YJ 7//额外的控制硬件

U8GLIB_ST7920_128X64_4X u8g(13, 12, 11);//配置屏幕针脚

int base = 0, ms = 0, s = 55 , mi = 59, hr = 5, week = 6;//进行初始化时间
int nMi = 0, nHr =  6;//闹钟时间
double tem = 0;//温度
char mode = 0;//模式

void setup() {
  pinMode(BUZZER, OUTPUT);
  pinMode(YJ, OUTPUT);
  u8g.setRot180();//旋转屏幕180度
  base = millis();//初始化基准时间
}

void loop() {
  func();//处理函数
  u8g.firstPage(); do draw(); while (u8g.nextPage());//刷新屏幕
}

void func() {
  if (map(analogRead(A2), 0, 1010, 0, 1) == 1) {
    switch (mode) {
      case 0: calc(); break; //更新时间
      case 1: hr = map(analogRead(A1), 0, 1020, 0, 23); break;//设置小时
      case 2: mi = map(analogRead(A1), 0, 1020, 0, 59); break;//设置分钟
      case 3: s = map(analogRead(A1), 0, 1020, 0, 59); break;//设置秒
      case 4: week = map(analogRead(A1), 0, 1020, 0, 6); break;//设置星期
      case 5: nHr = map(analogRead(A1), 0, 1020, 0, 23); break;//设置闹钟小时
      case 6: nMi = map(analogRead(A1), 0, 1020, 0, 59); break;//设置闹钟分钟
    }
  } else {
    mode = map(analogRead(A1), 0, 1010, 0, 6);//读取模式
    calc();//更新时间
  }

  tem = (double)analogRead(A0) * (5 / 10.23);//读取并计算温度
  if (hr == nHr && mi == nMi) {//播放闹钟1分钟
    digitalWrite(YJ, LOW);
    tone(BUZZER, 200 + ms);//随毫秒数改变闹钟音调，产生铃声
  } else {
    digitalWrite(YJ, HIGH);
    noTone(BUZZER);//结束播放铃声
    digitalWrite(BUZZER, LOW);//设置为低电平
  }
}

void calc() {
  ms = millis() - base;
  if (ms > 999) {
    ms = 0;
    base = millis() - 61; //用于校正误差,每过1s提前61ms
    if (++s > 59) {
      s = 0;
      base = millis() + 8; //用于校正误差,每过1min延迟8ms
      if (++mi > 59) {
        mi = 0;
        base = millis() - 38; //用于校正误差,每过1hour提前38ms
        if (++hr > 23) {
          hr = 0;
          base = millis() - 8; //用于校正误差,每过1day提前8ms
          if (++week > 6) week = 0;
        }
      }
    }
  }
}

void draw() {
  switch (mode) {
    case 0: {
        for (int x = 0; x < 2 * s; x++)//按照秒数绘制宽4个像素的进度条
          for (int y = 0; y < 4; y++)
            u8g.drawPixel(x + 5, y + 3);

        u8g.setFont(u8g_font_gdb30n);//设置gdb30像素数字类字体

        if (hr > 9) {//如果数字只有一位就添加0在前面
          u8g.setPrintPos( 8, 41);
        } else {
          u8g.drawStr(10, 41, "0");
          u8g.setPrintPos( 32, 41);
        }
        u8g.print(hr);

        if (s % 2 == 0)//冒号在秒数为偶数时才绘制，达到冒号闪烁的效果
          u8g.drawStr( 56, 37, ":");

        if (mi > 9) {//如果数字只有一位就添加0在前面
          u8g.setPrintPos( 70, 41);
        } else {
          u8g.drawStr(70, 41, "0");
          u8g.setPrintPos( 94, 41);
        }
        u8g.print(mi);

        u8g.setFont(u8g_font_gdb14r);//设置gdb14像素常用类字体
        switch (week) {//绘制星期数到屏幕
          case 0: u8g.drawStr(6, 61, "Sun"); break;
          case 1: u8g.drawStr(6, 61, "Mon"); break;
          case 2: u8g.drawStr(6, 61, "Tue"); break;
          case 3: u8g.drawStr(6, 61, "Wed"); break;
          case 4: u8g.drawStr(6, 61, "Thu"); break;
          case 5: u8g.drawStr(6, 61, "Fri"); break;
          default: u8g.drawStr(6, 61, "Sat");
        }

        u8g.setPrintPos( 56, 61);//绘制温度示数到屏幕
        u8g.print(tem);
        u8g.drawStr(111, 61, "C");
        break;
      }
    case 1: {
        u8g.setFont(u8g_font_gdb30n);//设置gdb30像素数字类字体
        if (hr > 9) {//如果数字只有一位就添加0在前面
          u8g.setPrintPos( 8, 41);
        } else {
          u8g.drawStr(10, 41, "0");
          u8g.setPrintPos( 32, 41);
        }
        u8g.print(hr);
        break;
      }
    case 2: {
        u8g.setFont(u8g_font_gdb30n);//设置gdb30像素数字类字体
        if (mi > 9) {//如果数字只有一位就添加0在前面
          u8g.setPrintPos( 70, 41);
        } else {
          u8g.drawStr(70, 41, "0");
          u8g.setPrintPos( 94, 41);
        }
        u8g.print(mi);
        break;
      }
    case 3: {
        for (int x = 0; x < 2 * s; x++)//按照秒数绘制宽4个像素的进度条
          for (int y = 0; y < 4; y++)
            u8g.drawPixel(x + 5, y + 3);

        u8g.setFont(u8g_font_gdb30n);//设置gdb30像素数字类字体
        if (s % 2 == 0)//冒号在秒数为偶数时才绘制，达到冒号闪烁的效果
          u8g.drawStr( 56, 37, ":");
        break;
      }
    case 4: {
        u8g.setFont(u8g_font_gdb14r);//设置gdb14像素常用类字体
        switch (week) {//绘制星期数到屏幕
          case 0: u8g.drawStr(6, 61, "Sun"); break;
          case 1: u8g.drawStr(6, 61, "Mon"); break;
          case 2: u8g.drawStr(6, 61, "Tue"); break;
          case 3: u8g.drawStr(6, 61, "Wed"); break;
          case 4: u8g.drawStr(6, 61, "Thu"); break;
          case 5: u8g.drawStr(6, 61, "Fri"); break;
          default: u8g.drawStr(6, 61, "Sat");
        }
        break;
      }
    case 5: {
        u8g.setFont(u8g_font_gdb30n);//设置gdb30像素数字类字体
        if (nHr > 9) {//如果数字只有一位就添加0在前面
          u8g.setPrintPos( 8, 41);
        } else {
          u8g.drawStr(10, 41, "0");
          u8g.setPrintPos( 32, 41);
        }
        u8g.print(nHr);
        break;
      }
    case 6: {
        u8g.setFont(u8g_font_gdb30n);//设置gdb30像素数字类字体
        if (nMi > 9) {//如果数字只有一位就添加0在前面
          u8g.setPrintPos( 70, 41);
        } else {
          u8g.drawStr(70, 41, "0");
          u8g.setPrintPos( 94, 41);
        }
        u8g.print(nMi);
        break;
      }
  }
}

注意

不同的机器和环境可能有不同的误差，建议自己进行校正后进行使用。