手动修改android模拟器system.img

所用工具已经打包上传：http://download.csdn.net/detail/asmcvc/6281473

参考文章：

《android 修改 system.img 方法》：http://wenku.baidu.com/view/6e611204e87101f69e31952d.html
《修改Android的system.img镜像》：http://android-anything.diandian.com/post/2011-09-28/5358289
《从官方原生ROM(system.img)定制update.zip刷机包》：http://wenku.baidu.com/view/e6d7f8150b4e767f5acfce9b.html

system.img文件：

adt-bundle-windows-x86\sdk\system-images\android-17\armeabi-v7a\system.img

工具：

unyaffs，mkyaffs2image

其中unyaffs有windows版本和linux版本，mkyaffs2image只有linux版本。

windows版本的unyaffs用法：

把system.img复制到unyaffs的相同目录下，cmd命令下cd到unyaffs的目录下，然后执行命令：unyaffs system.img 

unyaffs会把system.img解压到其目录下。

linux版本的unyaffs用法：

把unyaffs复制到/usr/bin目录下，并修改权限为可执行。

然后cd到system.img目录下（假定目录为system目录），执行命令：unyaffs system.img 

然后把system.img移动走，解包后的目录结构：

然后对system目录下的文件进行修改。

注意：修改完后的文件要修改一下权限，尽量和其他文件的权限保持一致。例如：chmod 644 framework-res.apk

mkyaffs2image用法：

复制到/usr/bin目录下，并修改权限为可执行。

这里以打包system目录为system.img为例，执行命令：

mkyaffs2image system system.img

然后把新生成的system.img复制替换掉原：adt-bundle-windows-x86\sdk\system-images\android-17\armeabi-v7a\system.img

执行bat批处理命令启动模拟器：

D:\adt-bundle-windows-x86\sdk\tools\emulator-arm.exe -avd AndroidVM -partition-size 128 

这里以修改android系统启动画面为例：

打开解包目录下的\framework\framework-res.apk

替换图片：framework-res.apk\assets\images\android-logo-mask.png为下图：

然后对\framework\framework-res.apk文件重新签名，复制到linux下后修改文件权限和原来一致。

然后mkyaffs2image system system.img打包生成新的system.img，替换原来的system.img，并启动模拟器，效果图如下：

修改代码：

工具：odextools（参考：《一键odex批量合并工具odextools的重新整理与使用》）、dexopt-wrapper

其中odextools.bat的代码：

::%%a %%a 
cls
@echo off&title 安卓论坛
setlocal EnableDelayedExpansion
color 1a
set di=%cd%
if not exist .\Major\ (
        echo.缺少Major请到bbs.hiapk.com重新下载！
    pause>nul
    exit
)
::::::::::::::::::::::::::::JAVA坏境判断::::::::::::::::::::::::
if not exist .\Major\jdk.kye goto ca
for /f "delims=" %%i in (.\Major\jdk.kye) do set pa=%%i
if not exist "!pa!"java.exe (
    goto ca 
    ) else (
    goto ca1
    )
:ca1
if not exist "!pa!"javac.exe (
    goto ca
    ) else (
    goto sta
    )
:ca
echo.
.\Major\echox -c 1c "                                     请等待。。。                               "
echo.
.\Major\echox -c 1b     工具正在检查你的JAVA环境，此检测界面跟你的计算机运行速度有关，一般在2~3分钟左右，当环境检查并收集完成后便会正常运行！
echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.&echo.
.\Major\echox -c 1d "                                            bbs.hiapk.com     "
.\Major\echox -c 1d "                                            安卓论坛          "
echo.                                                  %date% %time:~0,-6%
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist %%a:\nul (
        for /f "delims=" %%b in ('dir /a-d /s /b "%%a:\*javac.exe" 2^>nul') do (
            if /i "%%~nxb" equ "javac.exe" (
                set pa=%%~dpb
                if exist "!pa!"java.exe (
                    echo.%%~dpb>.\Major\jdk.kye
                    ) else (
                    echo.没有发现安装JDK环境！
                    pause>nul
                    exit
                    )
                )
            )
        )
    )
)
:sta
cls
set Path=%Path%;%pa%
::::::::::::::::::::::::::::判断操作系统::::::::::::::::::::::::
set "32bit="
set "64bit="
if /i "%PROCESSOR_IDENTIFIER:~0,3%"=="X86" (
    set 32bit=::
    ) else (
    set 64bit=::
    )
set co=echox -c 1e ┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:menu
cd /d !di!
cls
set "Catalogue="
set "Suffix="
if "!32bit!" equ "" (
    .\Major\echox -c 1d 　　　　　　　　　　　　　　　☆当前为64位操作系统☆
    ) else (
    .\Major\echox -c 1d 　　　　　　　　　　　　　　　★当前为32位操作系统★
    )
echo.1-合并app目录
echo.2-合并app目录并签名apk文件
echo.3-合并framework目录
echo.4-分解ode文件
echo.5-编译ode文件
set /p Choice=请选择一个项目：
set sing=0
if !Choice! equ 1 (
    set Catalogue=app
    set Suffix=apk
    goto fapp
    )
if !Choice! equ 2 (
    set sing=1
    set Catalogue=app
    set Suffix=apk
    goto fapp
    )
if !Choice! equ 3 (
    set Catalogue=framework
    set Suffix=jar
    goto fapp
    )
if !Choice! equ 4 goto xdex
if !Choice! equ 5 goto odex
goto menu
:fapp
::---------------------------------------odex处理----------------------------------------::
::::::::::::::::::::::::::::目录条件判断::::::::::::::::::::::::
cls
if not exist .\romdir\system\framework\ (
    echo.没有发现framework目录！将正确解好的ROM所有目录及文件放到romdir目录下！
    pause>nul
    goto menu
)
if not exist .\romdir\system\app\ (
    echo.没有发现app目录！将正确解好的ROM所有目录及文件放到romdir目录下！
    pause>nul
    goto menu
)
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
del /f .\romdir\system\framework\baksmali.jar .\romdir\system\framework\smali.jar .\romdir\system\framework\echox.exe .\romdir\system\framework\7z32.exe .\romdir\system\framework\7z64.exe .\romdir\system\framework\7z.dll .\romdir\system\app\baksmali.jar .\romdir\system\app\smali.jar .\romdir\system\app\echox.exe .\romdir\system\app\7z32.exe .\romdir\system\app\7z64.exe .\romdir\system\app\7z.dll 1>nul 2>nul
rd /s /q .\romdir\system\framework\out 1>nul 2>nul
rd /s /q .\romdir\system\app\out 1>nul 2>nul
:::::::::::::::::::获取framework工作目录所需变量:::::::::::::::::
del /f %temp%\work 1>nul 2>nul
for %%i in (.\romdir\system\framework\*.jar) do set /p =:%%~nxi<nul>>%temp%\work
for /f "delims=" %%i in ('type %temp%\work') do set work=%%i
del /f %temp%\work 1>nul 2>nul
::=============================================================::
for %%i in (baksmali.jar smali.jar echox.exe signapk.jar testkey.x509.pem testkey.pk8) do copy .\Major\%%i .\romdir\system\!Catalogue!\ 1>nul 2>nul
!64bit!copy .\Major\7z32.exe .\romdir\system\!Catalogue!\ 1>nul 2>nul
!32bit!copy .\Major\7z64.exe .\romdir\system\!Catalogue!\ 1>nul 2>nul
!64bit!copy .\Major\7z32.dll .\romdir\system\!Catalogue!\7z.dll 1>nul 2>nul
!32bit!copy .\Major\7z64.dll .\romdir\system\!Catalogue!\7z.dll 1>nul 2>nul
:::::::::::::::::::::::::改变当前操作目录::::::::::::::::::::::::
cd /d .\romdir\system\!Catalogue!\
:::::::::::::::::::::获取当前所有要合并的文件::::::::::::::::::::
set "shu1="
for %%a in (..\!Catalogue!\*.odex) do set /a shu1+=1
if "!shu1!" equ "" set shu1=0
!co!&echo.发现!shu1!个odex文件！
:::::::::::::::::::::::::::::开始合并::::::::::::::::::::::::::::
set "shu="
for %%b in (..\!Catalogue!\*.odex) do (
    set /a shu+=1
    set apkx=%%~nb
    !co!
    echo.处理!shu1!中的第!shu!个 ...
    if not exist !apkx!.!Suffix! (
        echox -c 1d 没有找到!apkx!.!Suffix!文件！
        echox -c 1d 合并!apkx!.!Suffix!结束！
    ) else (
        echo.开始分解!apkx!.odex ...
        Java -Xmx512M -jar baksmali.jar -d ..\framework -x !apkx!.odex
        if !ERRORLEVEL! equ 1 (
            echox -c 1d "警告：分解!apkx!.odex失败！开始尝试强制分解 ..."
            Java -Xmx512M -jar baksmali.jar -d ..\framework -c !work! -x !apkx!.odex
            if !ERRORLEVEL! equ 1 (
                echox -c 1d "强制分解!apkx!.odex失败！
                echox -c 1d "文件!apkx!.odex与!apkx!.!Suffix!没有改变！"
            ) else (
                echo.生成classes.dex文件 ...
                java -Xmx512M -jar smali.jar out -o classes.dex
                echo.将classes.dex打包到!apkx!.!Suffix!
                !32bit!7z64.exe a -tzip !apkx!.!Suffix! classes.dex 1>nul 2>nul
                !64bit!7z32.exe a -tzip !apkx!.!Suffix! classes.dex 1>nul 2>nul
                if !sing! equ 1 (
                    ren !apkx!.!Suffix! __.apk
                    echo.开始对!apkx!.!Suffix!进行签名 ...
                    java -Xmx512M -jar signapk.jar testkey.x509.pem testkey.pk8 __.apk !apkx!.!Suffix!
                )
                del /f __.apk 1>nul 2>nul
                del /f !apkx!.odex 1>nul 2>nul
                del /f classes.dex 1>nul 2>nul
                rd /s /q out 1>nul 2>nul
            )
        ) else (
            echo.生成classes.dex文件 ...
            java -Xmx512M -jar smali.jar out -o classes.dex
            echo.将classes.dex打包到!apkx!.!Suffix!
            !32bit!7z64.exe a -tzip !apkx!.!Suffix! classes.dex 1>nul 2>nul
            !64bit!7z32.exe a -tzip !apkx!.!Suffix! classes.dex 1>nul 2>nul
            if !sing! equ 1 (
                ren !apkx!.!Suffix! __.apk
                echo.开始对!apkx!.!Suffix!进行签名 ...
                java -Xmx512M -jar signapk.jar testkey.x509.pem testkey.pk8 __.apk !apkx!.!Suffix!
            )
            echo.移除!apkx!.odex文件 ... 
            del /f __.apk 1>nul 2>nul
            del /f !apkx!.odex 1>nul 2>nul
            del /f classes.dex 1>nul 2>nul
            rd /s /q out 1>nul 2>nul
        )
    )
)
for %%i in (7z32.exe 7z64.exe 7z.dll baksmali.jar smali.jar echox.exe signapk.jar testkey.x509.pem testkey.pk8) do del /f %%i 1>nul 2>nul
echo.&echo.操作结束！
pause>nul
goto menu
::-------------------------------------odex处理结束--------------------------------------::
::----------------------------------------dex处理----------------------------------------::
:xdex
cls
if not exist .\dex\classes.dex (
    echo.dex目录下没有发现classes.dex文件！
    pause>nul
    goto menu
)
echo.开始分解dex文件 ...
Java -Xmx512M -jar .\Major\baksmali.jar .\dex\classes.dex -o .\dex\out
cls
echo.dex分解完成，输出在：\dex\out
pause>nul
goto menu
:odex
cls
if not exist .\dex\classes.dex (
    echo.dex目录下没有发现out目录！
    pause>nul
    goto menu
)
echo.开始反编回dex文件 ...
java -Xmx512M -jar .\Major\smali.jar .\dex\out -o .\dex\out\classes.dex
cls
echo.dex编译完成，输出在：\dex\out\classes.dex
pause>nul
goto menu
::--------------------------------------dex处理结束--------------------------------------:: 

批处理有一处bug：每打包一次会把odex文件删除掉，导致在后面的打包过程中会出现找不到：system/framework/core.odex类似的错误，因此只需要在打包完后不删除odex文件即可，找到del /f !apkx!.odex 1>nul 2>nul改为：::del /f !apkx!.odex 1>nul 2>nul，也就是注释掉这一行代码。

具体使用方法（操作在windows下）：

在odextools\romdir目录下创建文件夹：system

利用unyaffs解包system.img后，把所有文件复制到system目录下。

然后运行odextools.bat，如图：

选择一个需要整合odex的目录选项即可。odextools.bat会自动设置环境变量，使用baksmali.jar来反编译odex为smali，然后再调用smali.jar打包为classes.dex，

然后再打包到相应的apk包（framework目录下对应的是jar后缀的，实际上也是个apk包），最后再重新签名。

如果要修改代码，则需要把上面重新打包生成的apk文件，利用常规方法反编译后修改smali代码，例如插桩输入log信息。然后再回编译并重新签名。

最后一步：因为system.img中的apk是优化过的，apk主目录下是没有classes.dex文件的，而是一个被优化过的odex文件，用于优化启动速度。

因此需要将修改后的apk包再用dexopt-wrapper优化apk包后生成出odex文件，然后删除apk包里的classes.dex，并在相同目录下放置与apk包同名的odex文件。

按照原system目录的文件结构组织好后，目录复制到linux环境下使用mkyaffs2image重新打包成system.img。