屏蔽word的快捷键、菜单、工具栏

VBA：主界面_复制等快捷键_右键菜单____禁用/恢复

　　请 hnymx2005 兄试试以下代码：


'查找需要的窗口
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" _
        (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
'取得窗口样式位
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" _
        (ByVal hWnd As Long, ByVal nIndex As Long) As Long
'设置窗口样式位
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" _
        (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
'重绘窗体标题栏
Private Declare Function DrawMenuBar Lib "user32" (ByVal hWnd As Long) As Long

'以下定义常数及变量
Private Const GWL_STYLE = (-16)   '窗口样式
Private Const WS_CAPTION = &HC00000  ' WS_BORDER Or WS_DLGFRAME


Sub 主界面_复制等快捷键_右键菜单____禁用()
'2010.02.06 雨雪霏霏试写。

'隐藏标题栏的方法见konggs版主在《如何使用vba隐藏word的标题栏？》6楼的帖子，
'链接为：http://club.excelhome.net/viewthread.php?tid=196700。

'屏蔽右键菜单方法采自 minsoft 在《如何彻底屏蔽右键选项》5楼的帖子，
'链接为：http://club.excelhome.net/thread-201692-1-1.html。


    Dim Istype As Long, hWnd As Long, i As Integer
    With ActiveDocument
   
   
        hWnd = FindWindow("OpusApp", vbNullString)
        'Excel改成  hWnd = FindWindow("XLMAIN", vbNullString)
        Istype = GetWindowLong(hWnd, GWL_STYLE)    '取得窗口样式位
        Istype = Istype And Not WS_CAPTION    '窗体样式位: 原样式无标题栏
        SetWindowLong hWnd, GWL_STYLE, Istype    '重设窗体样式位
        DrawMenuBar hWnd    '重绘窗体标题栏


        CommandBars.ActiveMenuBar.Enabled = False    '隐藏菜单栏
        CommandBars("Formatting").Visible = False    '隐藏“格式”工具栏
        CommandBars("Standard").Visible = False    '隐藏“常用”工具栏
        ActiveWindow.DisplayRulers = False    '隐藏标尺栏
        ActiveWindow.DisplayHorizontalScrollBar = False    '隐藏水平滚动条
        Application.DisplayStatusBar = False    '隐藏状态栏



        FindKey(BuildKeyCode(wdKeyControl, wdKeyC)).Disable    '屏蔽“复制”快捷键
        FindKey(BuildKeyCode(wdKeyControl, wdKeyInsert)).Disable    '屏蔽“复制”快捷键

        FindKey(BuildKeyCode(wdKeyControl, wdKeyV)).Disable    '屏蔽“粘贴”快捷键
        FindKey(BuildKeyCode(wdKeyShift, wdKeyInsert)).Disable    '屏蔽“粘贴”快捷键

        FindKey(BuildKeyCode(wdKeyControl, wdKeyX)).Disable    '屏蔽“剪切”快捷键
        FindKey(BuildKeyCode(wdKeyShift, wdKeyDelete)).Disable    '屏蔽“剪切”快捷键

        FindKey(BuildKeyCode(wdKeyControl, wdKeyP)).Disable    '屏蔽“打印”快捷键
        FindKey(BuildKeyCode(wdKeyControl, wdKeyShift, wdKeyF12)).Disable    '屏蔽“打印”快捷键

        FindKey(BuildKeyCode(wdKeyAlt, wdKeyControl, wdKeyI)).Disable    '屏蔽“打印预览”快捷键
        FindKey(BuildKeyCode(wdKeyControl, wdKeyF2)).Disable    '屏蔽“打印预览”快捷键

        FindKey(BuildKeyCode(wdKeyControl, wdKeyS)).Disable    '屏蔽“保存”快捷键
        FindKey(BuildKeyCode(wdKeyShift, wdKeyF12)).Disable    '屏蔽“保存”快捷键
        FindKey(BuildKeyCode(wdKeyAlt, wdKeyShift, wdKeyF2)).Disable    '屏蔽“保存”快捷键

        FindKey(wdKeyF12).Disable    '屏蔽“另存为”快捷键


        For i = 1 To .CommandBars.Count
            If .CommandBars(i).Type = 2 Then
                .CommandBars(i).Enabled = False    '屏蔽右键菜单
            End If
        Next

    End With

End Sub


Sub 主界面_复制等快捷键_右键菜单____还原()
    Dim Istype As Long, hWnd As Long, i As Integer
    With ActiveDocument


        hWnd = FindWindow("OpusApp", vbNullString)    '取得窗口样式位
        Istype = GetWindowLong(hWnd, GWL_STYLE)
        Istype = Istype Or WS_CAPTION    '窗体样式位: 原样式和标题栏
        SetWindowLong hWnd, GWL_STYLE, Istype    '重设窗体样式位
        DrawMenuBar hWnd    '重绘窗体标题栏


        CommandBars.ActiveMenuBar.Enabled = True    '显示菜单栏
        CommandBars("Formatting").Visible = True    '显示“格式”工具栏
        CommandBars("Standard").Visible = True    '显示“常用”工具栏
        ActiveWindow.DisplayRulers = True    '显示标尺栏
        ActiveWindow.DisplayHorizontalScrollBar = True    '显示水平滚动条
        Application.DisplayStatusBar = True    '显示状态栏



        FindKey(BuildKeyCode(wdKeyControl, wdKeyC)).Rebind _
            KeyCategory:=wdKeyCategoryCommand, Command:="EditCopy"   '恢复“复制”快捷键
        FindKey(BuildKeyCode(wdKeyControl, wdKeyInsert)).Rebind _
            KeyCategory:=wdKeyCategoryCommand, Command:="EditCopy"   '恢复“复制”快捷键"

        FindKey(BuildKeyCode(wdKeyControl, wdKeyV)).Rebind _
            KeyCategory:=wdKeyCategoryCommand, Command:="EditPaste"   '恢复“粘贴”快捷键"
        FindKey(BuildKeyCode(wdKeyShift, wdKeyInsert)).Rebind _
            KeyCategory:=wdKeyCategoryCommand, Command:="EditPaste"   '恢复“粘贴”快捷键

        FindKey(BuildKeyCode(wdKeyControl, wdKeyX)).Rebind _
            KeyCategory:=wdKeyCategoryCommand, Command:="EditCut"   '恢复“剪切”快捷键
        FindKey(BuildKeyCode(wdKeyShift, wdKeyDelete)).Rebind _
            KeyCategory:=wdKeyCategoryCommand, Command:="EditCut"   '恢复“剪切”快捷键

        FindKey(BuildKeyCode(wdKeyControl, wdKeyP)).Rebind _
            KeyCategory:=wdKeyCategoryCommand, Command:="FilePrint"   '恢复“打印”快捷键
        FindKey(BuildKeyCode(wdKeyControl, wdKeyShift, wdKeyF12)).Rebind _
            KeyCategory:=wdKeyCategoryCommand, Command:="FilePrint"   '恢复“打印”快捷键

        FindKey(BuildKeyCode(wdKeyAlt, wdKeyControl, wdKeyI)).Rebind _
            KeyCategory:=wdKeyCategoryCommand, Command:="FilePrintPreview"   '恢复“打印预览”快捷键
        FindKey(BuildKeyCode(wdKeyControl, wdKeyF2)).Rebind _
            KeyCategory:=wdKeyCategoryCommand, Command:="FilePrintPreview"   '恢复“打印预览”快捷键

        FindKey(BuildKeyCode(wdKeyControl, wdKeyS)).Rebind _
            KeyCategory:=wdKeyCategoryCommand, Command:="FileSave"   '恢复“保存”快捷键
        FindKey(BuildKeyCode(wdKeyShift, wdKeyF12)).Rebind _
            KeyCategory:=wdKeyCategoryCommand, Command:="FileSave"   '恢复“保存”快捷键
        FindKey(BuildKeyCode(wdKeyAlt, wdKeyShift, wdKeyF2)).Rebind _
            KeyCategory:=wdKeyCategoryCommand, Command:="FileSave"   '恢复“保存”快捷键

        FindKey(wdKeyF12).Rebind _
            KeyCategory:=wdKeyCategoryCommand, Command:="FileSaveAs"   '恢复“另存为”快捷键


        For i = 1 To .CommandBars.Count
            If .CommandBars(i).Type = 2 Then
                .CommandBars(i).Enabled = True    '恢复右键菜单
            End If
        Next

    End With
End Sub