hp服务器ilo批量配置脚本

 hp 服务器ilo批量配置脚本

hp的ilo是一个非常方便的带外管理工具，在平时使用的时候，经常有大量的hp服务器需要配置ilo，下面是我下的一个脚本，可以批量的完成hp服务器ilo配置。

 

脚本功能：

1 自动升级ilo固件；

2 自动加入test.com的域，注意域dns在adcfg.xml文件中要配置正确；

 

使用方法 

auto_cfg_ilo3 ilo的ip ilo的user ilouse的password

 

注意事项：

1 固件升级文件放在当前目录下面；

2 需要进入当前目录运行

 

脚本如下：

批处理用到的固件和xml可以在以下地址下载：

http://down.51cto.com/data/485196

 

@echo off
rem *****自动升级ilo固件和加入域认证脚本
rem *****作者xiaoli110
rem *****原理
rem *****通过批处理调用相应的xml文件来执行相关操作
rem *****先升级固件，然后重启，然后配置ad认证，在重启

echo 自动升级ilo固件和加入域认证脚本
sleep.exe 2

echo 参数检查
sleep.exe 5
if "%1"=="" goto err_input
if "%2"=="" goto err_input
if "%3"=="" goto err_input
echo 参数正确

echo 连接测试
sleep.exe 5
CPQLOCFG.EXE -s %1  -f get_all_users.xml -v -l log.txt -u %2 -p %3 |findstr "succeeded"
if errorlevel  1 (
    goto err_con
  ) else (
    echo 连接成功
  )


echo 开始固件升级,可能需要5分钟左右
sleep.exe 5
CPQLOCFG.EXE -s %1  -f Update_Firmware.xml -v -l log.txt -u %2 -p %3



echo 重启ilo3，需要60秒，请等待
sleep.exe 5
CPQLOCFG.EXE -s %1  -f reset_rib.xml -v -l log.txt -u %2 -p %3

:con_again
sleep.exe 20
echo 连接测试
sleep.exe 5
CPQLOCFG.EXE -s %1  -f get_all_users.xml -v -l log.txt -u %2 -p %3 |findstr "succeeded"
if errorlevel  1 (
    goto con_again
  ) else (
    echo 连接成功
  )


echo 开始配置ad认证
sleep.exe 5
CPQLOCFG.EXE -s %1 -f adcfg.xml -v -l log.txt -u %2 -p %3

echo 重启ilo3，需要60秒，请等待
sleep.exe 5
CPQLOCFG.EXE -s %1 -f reset_rib.xml -v -l log.txt -u %2 -p %3

:con_again2
sleep.exe 20
echo 连接测试
sleep.exe 5
CPQLOCFG.EXE -s %1  -f get_all_users.xml -v -l log.txt -u %2 -p %3 |findstr "succeeded"
if errorlevel  1 (
    goto con_again2
  ) else (
    echo 连接成功
  )


echo 完成
goto end

:err_input
echo 参数输入错误，请检查输入的参数，依次为主机名、用户、密码
goto end

:err_con
echo 连接测试失败，请检查输入主机名、用户、密码是否正确
goto end

:end
@echo on