SQL Server查看事务锁

SELECT
       Blocked.Session_ID AS Blocked_Session_ID
       , Blocked_SQL.text AS Blocked_SQL
       , waits.wait_type AS Blocked_Resource
       , Blocking.Session_ID AS Blocking_Session_ID
       , Blocking_SQL.text AS Blocking_SQL
        , GETDATE()
FROM sys.dm_exec_connections AS Blocking INNER JOIN sys.dm_exec_requests AS Blocked
       ON Blocked.Blocking_Session_ID = Blocking.Session_ID
CROSS APPLY
       (
         SELECT * FROM sys.dm_exec_sql_text(Blocking.most_recent_sql_handle)
       ) AS Blocking_SQL
CROSS APPLY
       (
         SELECT * FROM sys.dm_exec_sql_text(Blocked.sql_handle)
       ) AS Blocked_SQL
INNER JOIN sys.dm_os_waiting_tasks AS waits 
       ON waits.Session_ID = Blocked.Session_ID
 
 
-- What SQL Statements Are Currently Running?

SELECT 'Duration(secs)' = datediff(ss,start_time, getdate()) 
, [Spid] = session_Id
, ecid
, [Database] = DB_NAME(sp.dbid)
, [User] = nt_username
, [Status] = er.status
, [Wait] = wait_type
, [Individual Query] = SUBSTRING (qt.text, er.statement_start_offset/2,
(CASE WHEN er.statement_end_offset = -1
 THEN LEN(CONVERT(NVARCHAR(MAX), qt.text)) * 2
 ELSE er.statement_end_offset END - er.statement_start_offset)/2)
,[Parent Query] = qt.text
, Program = program_name
, Hostname
, nt_domain
, start_time
FROM sys.dm_exec_requests er
INNER JOIN sys.sysprocesses sp ON er.session_id = sp.spid
CROSS APPLY sys.dm_exec_sql_text(er.sql_handle)as qt
WHERE session_Id > 50              -- Ignore system spids.
AND session_Id NOT IN (@@SPID)     -- Ignore this current statement.
ORDER BY 1 DESC, 2