NOIP2018普及组复赛试题第4题解析

NOIP2018普及组复赛试题第4题解析

第4题：对称二叉树
题目描述
一棵有点权的有根树如果满足以下条件，则被轩轩称为对称二叉树：
二叉树；
将这棵树所有节点的左右子树交换，新树和原树对应位置的结构相同且点权相等。
下图中节点内的数字为权值，节点外的 id表示节点编号。
现在给出一棵二叉树，希望你找出它的一棵子树，该子树为对称二叉树，且节点数 最多。请输出这棵子树的节点数。
注意：只有树根的树也是对称二叉树。本题中约定，以节点 T为子树根的一棵“子 树”指的是：节点T和它的全部后代节点构成的二叉树。
输入输出格式
输入格式：
第一行一个正整数 n，表示给定的树的节点的数目，规定节点编号1∼n，其中节点 1 是树根。
第二行 n个正整数，用一个空格分隔，第 i个正整数 v_i 代表节点 i 的权值。
接下来 n 行，每行两个正整数 l_i, r_i,分别表示节点 ii 的左右孩子的编号。如果不存在左 / 右孩子，则以 -1表示。两个数之间用一个空格隔开。
输出格式：
输出文件共一行，包含一个整数，表示给定的树的最大对称二叉子树的节点数。
输入输出样例
输入样例#1：
2
1 3
2 -1
-1 -1
输出样例#1：
1
输入样例#2：
10
2 2 5 5 5 5 4 4 2 3
9 10
-1 -1
-1 -1
-1 -1
-1 -1
-1 2
3 4
5 6
-1 -1
7 8
输出样例#2：
3
说明
【输入输出样例 1 说明】
最大的对称二叉子树为以节点2为树根的子树，节点数为1。
【输入输出样例 2 说明】
最大的对称二叉子树为以节点7为树根的子树，节点数为3。

  a,l,r:array[1..1000000]of longint;
  n,i,x,max:longint;
function dfs(x,y:longint):longint;//比较两颗子树是否对称并累计节点数量
var
  t:longint;
begin
  if (a[x]<>a[y]) or ((l[x]>0)<>(r[y]>0)) or ((l[y]>0)<>(r[x]>0)) then//如果两颗子树的根的权值不一样或者结构不一样
    exit(0);                   //不对，退出
  dfs:=2;
  if l[x]>0 then               //如果有左子树的左子树的话（也就是有右子树的右子树）
  begin
    t:=dfs(l[x],r[y]);         //比较左子树的左子树和右子树的右子树
    if t=0 then                //如果不对
      exit(0);                 //不对，退出
    inc(dfs,t);                //累计节点数量
  end;
  if l[y]>0 then               //基本同上
  begin
    t:=dfs(l[y],r[x]);         //比较左子树的右子树和右子树的左子树
    if t=0 then
      exit(0);
    inc(dfs,t);
  end;
end;
function f(x:longint):longint; //计算以x为根的对称二叉树的节点数量
begin
  if (l[x]=-1) and (r[x]=-1) then//如果是叶子节点
    exit(1)                    //不用搜了，反正就一个根节点
  else
    if (l[x]=-1) or (r[x]=-1) then//如果有左子树没右子树或者有右子树没左子树
      exit(0)                  //不对称，返回0
    else
      exit(dfs(l[x],r[x])+1);  //比较左子树和右子树，再加上根节点（如果不对称就返回1，不过并没有什么关系）
end;
begin
  read(n);
  for i:=1 to n do             //读入
    read(a[i]);
  for i:=1 to n do
    read(l[i],r[i]);
  max:=0;
  for i:=1 to n do             //枚举对称二叉树的根节点
  begin
    x:=f(i);
    if x>max then
      max:=x;
  end;
  writeln(max);
end.