Shader 学习笔记(9) Ramp贴图

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'

Shader "wx/Ramp"{
	Properties{
		_Color("Color",Color)=(1,1,1,1)
		_RampTex("Ramp Tex",2D)="white"{}
		_Specular("Specular",Color)=(1,1,1,1)
		_Gloss("Gloss",Range(8.0,256))=20
	}
	SubShader{
		Pass{
			Tags{"LightMode"="ForwardBase"}
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#include "Lighting.cginc"
			fixed4 _Color;
			sampler2D _RampTex;
			float4 _RampTex_ST;
			fixed4 _Specular;
			float _Gloss;
			struct a2v
			{
				float4 vertex:POSITION;
				float3 normal:NORMAL;
				float4 texcoord:TEXCOORD0;
			};
			struct v2f
			{
				float4 pos:SV_POSITION;
				float3 worldNormal:TEXCOORD0;
				float3 worldPos:TEXCOORD1;
				float2 uv:texcoord2;
			};
			v2f vert(a2v v){
				v2f o;
				o.pos=UnityObjectToClipPos(v.vertex);       
				o.worldNormal=normalize(UnityObjectToWorldNormal(v.normal)); //获取归一化世界坐标法线
				o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;   //获取世界坐标位置
				o.uv=TRANSFORM_TEX(v.texcoord,_RampTex);            //计算_RampTex贴图的OFFSET,TILIN后,赋值给UV
				return o;
			}
			fixed4 frag(v2f i):SV_Target{
				fixed3 worldLightDir=normalize(UnityWorldSpaceLightDir(i.worldPos));  //计算世界坐标灯光方向向量
				fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;                    //获取环境光
				fixed halfLambert=0.5*dot(i.worldNormal,worldLightDir)+0.5;     //半兰伯特灯光模型 
				fixed3 diffuseColor=tex2D(_RampTex,fixed2(halfLambert,halfLambert)).rgb*_Color.rgb; /*tex2D纹理采
				样(Tex2D(sampler2D tex, float2 s)二维纹理查询),sampler2D tex等于纹理名字,float2 s代表UV坐标.就是
				用float2 s的uv,来适配tex的纹理.本例的UV就是兰伯特光照模型.*/
				fixed3 diffuse=_LightColor0.rgb*diffuseColor;
				fixed3 viewDir=normalize(UnityWorldSpaceViewDir(i.worldPos));   //获取归一化摄像机方向
				fixed3 halfDir=normalize(worldLightDir+viewDir);              //获取归一化半视角
				fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(max(0,dot(i.worldNormal,halfDir)),_Gloss);
				return fixed4(ambient+diffuse+specular,1.0);
			}
			ENDCG
		}
	}
	FallBack"Specular"
}