4_EXECUTE IMMEDIATE用法

解析并马上执行动态的SQL语句或非运行时创建的PL/SQL块.动态创建和执行SQL语句性能超前。
使用技巧

1. EXECUTE IMMEDIATE将不会提交一个DML事务执行，应该显式提交
   如果通过EXECUTE IMMEDIATE处理DML命令，
   那么在完成以前需要显式提交或者作为EXECUTE IMMEDIATE自己的一部分.
   如果通过EXECUTE IMMEDIATE处理DDL命令,它提交所有以前改变的数据
2. 不支持返回多行的查询,这种交互将用临时表来存储记录(参照例子如下)或者用REF cursors.
3. 当执行SQL语句时，不要用分号，当执行PL/SQL块时，在其尾部用分号;.
4. 在Oracle手册中，未详细覆盖这些功能。
   下面的例子展示了所有用到Execute immediate的可能方面.希望能给你带来方便.
5. 对于Forms开发者,当在PL/SQL 8.0.6.3.版本中，Forms 6i不能使用此功能.
   EXECUTE IMMEDIATE -- 用法例子
6. 在PL/SQL运行DDL语句
   begin
   execute immediate 'set role all';
   end;
7. 给动态语句传值(USING 子句)
   declare
   l_depnam varchar2(20) := 'testing';
   l_loc varchar2(10) := 'Dubai';
   begin
   execute immediate 'insert into dept values (:1, :2, :3)'
   using 50, l_depnam, l_loc;
   commit;
   end;
8. 从动态语句检索值(INTO子句)
   declare
   l_cnt varchar2(20);
   begin
   execute immediate 'select count(1) from emp'
   into l_cnt;
   dbms_output.put_line(l_cnt);
   end;
9. 动态调用例程.例程中用到的绑定变量参数必须指定参数类型.
   黓认为IN类型,其它类型必须显式指定
   declare
   l_routin varchar2(100) := 'gen2161.get_rowcnt';
   l_tblnam varchar2(20) := 'emp';
   l_cnt number;
   l_status varchar2(200);
   begin
   execute immediate 'begin ' || l_routin || '(:2, :3, :4); end;'
   using in l_tblnam, out l_cnt, in out l_status;
   if l_status != 'OK' then
   dbms_output.put_line('error');
   end if;
   end;
10. 将返回值传递到PL/SQL记录类型;同样也可用%rowtype变量
    declare
    type empdtlrec is record (empno number(4),
    ename varchar2(20),
    deptno number(2));
    empdtl empdtlrec;
    begin
    execute immediate 'select empno, ename, deptno ' ||
    'from emp where empno = 7934'
    into empdtl;
    end;
11. 传递并检索值.INTO子句用在USING子句前
    declare
    l_dept pls_integer := 20;
    l_nam varchar2(20);
    l_loc varchar2(20);
    begin
    execute immediate 'select dname, loc from dept where deptno = :1'
    into l_nam, l_loc
    using l_dept ;
    end;
12. 多行查询选项.对此选项用insert语句填充临时表，
    用临时表进行进一步的处理,也可以用REF cursors纠正此缺憾.
    declare
    l_sal pls_integer := 2000;
    begin
    execute immediate 'insert into temp(empno, ename) ' ||
    ' select empno, ename from emp ' ||
    ' where sal > :1'
    using l_sal;
    commit;
    end;
    对于处理动态语句,EXECUTE IMMEDIATE 比以前可能用到的更容易并且更高效.
    当意图执行动态语句时，适当地处理异常更加重要.应该关注于捕获所有可能的异常.