Unity Shader 逐像素Blinn-Phong高光反射（八）

Unity Shader系列文章：Unity Shader目录-初级篇

Unity Shader系列文章：Unity Shader目录-中级篇

效果：

Blinn-Phong逐像素光照.jpg

Phong逐顶点光照、Phong逐像素光照、Blinn-Phong逐像素光照：

Phong逐顶点光照、Phong逐像素光照、Blinn-Phong逐像素光照.jpg

Blinn-Phong高光反射公式：

：入射光颜色；
：高光反射颜色；
：单位法向量；
：单位半角向量，由光线和视线夹角一半方向上的单位向量计算得出：
（shader中计算：normalize(V + L)）
：反射系数；

// Blinn-Phong逐像素高光反射
Shader "Custom/Specular/BlinnPhongSpecularPixel"
{
    Properties
    {
        _Diffuse ("Diffuse", Color) = (1, 1, 1, 1) // 漫反射颜色
        _Specular ("Specular", Color) = (1, 1, 1, 1) // 高光反射颜色
        _Gloss ("Gloss", Range(8, 256)) = 20 // 高光区域大小
    }
    
    SubShader
    {
        Tags { "RenderType" = "Opaque" }
        LOD 100
        
        pass
        {
            Tags { "LightMode" = "ForwardBase" }
            
            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag
            
            #include "Lighting.cginc"
            
            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;
            
            // 应用传递给顶点着色器的数据
            struct a2v
            {
                float4 vertex: POSITION;
                fixed3 normal: NORMAL;
            };
            
            // 顶点着色器传递给片元着色器的数据
            struct v2f
            {
                float4 pos: SV_POSITION;
                float3 worldNormal: TEXCOORD0;
                float3 worldPos: TEXCOORD1;
            };
            
            // 顶点着色器函数
            v2f vert(a2v v)
            {
                v2f o;
                // 将顶点坐标从模型空间变换到裁剪空间
                // 等价于o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
                o.pos = UnityObjectToClipPos(v.vertex);
                
                // 将法线从模型空间变换到世界空间
                // 等价于o.worldNormal = mul(v.normal, (float3x3)unity_WorldToObject);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                
                // 将顶点从模型空间变换到世界空间
                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
                
                return o;
            }
            
            // 片元着色器
            fixed4 frag(v2f i): SV_TARGET
            {
                // 获得世界空间下单位光向量
                float3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                
                // 计算漫反射
                // 兰伯特公式：Id = Ip * Kd * N * L
                // IP：入射光的光颜色；
                // Kd：漫反射系数 ( 0 ≤ Kd ≤ 1)；
                // N：单位法向量，L：单位光向量
                float3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(i.worldNormal, worldLightDir));
                
                // 获得观察方向
                float3 viewDir = normalize(_WorldSpaceLightPos0.xyz - i.worldPos.xyz);
                
                // 获得半向量
                float3 halfDir = normalize(worldLightDir + viewDir);
                
                // 计算高光反射
                // Blinn-Phong高光反射公式：
                // Cspecular=(Clight ⋅ Mspecular)max(0,n.h)^mgloss
                // Clight：入射光颜色；
                // Mspecular：高光反射颜色；
                // n: 单位法向量；
                // h: 半角向量：光线和视线夹角一半方向上的单位向量
                // h = (V + L)/(| V + L |)
                // mgloss：反射系数；
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(i.worldNormal, halfDir)), _Gloss);
                
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                return fixed4(ambient + diffuse + specular, 1);
            }
            
            ENDCG
            
        }
    }
}