Cython系列教程：五.练习题：求素数

1 Cyhton的编译方法

首先我们创建一个helloworld.pyx:

# pyx 文件
print('Hello World')

接下来看一下两种编译C的方式
1） setuptools的方式

from setuptools import setup
from Cython.Build import cythonize

setup(
    ext_modules = cythonize("helloworld.pyx")
)

然后执行命令：python setup.py build_ext --inplace,然后就可以在py文件中按照常规模块的导入方式进行导入了。
2）pyximport 的方式

>>> import pyximport   # 导入pyximport
>>> pyximport.install()  # 初始化
>>> import helloworld    #导入我们要的模块 
Hello World

pyximport还支持导入常规的python模块，它的编译过程是在执行过程中进行的，所以运行到import helloworld这一行的时候会比较 慢，因为需要先编译。需要注意的是，当遇到Cython编译不了的情况，默认是按照python正常导入模块的方式进行导入的，也就是说，pyximport并不发挥作用。

2 看一个求素数的案例

首先，在Cython中我们用C定义一个求素数的函数primes：

# 文件：primes_c.pyx
# 用C的方式写求素数函数
def primes(int nb_primes):
    cdef int n, i, len_p
    cdef int p[1000]
    if nb_primes > 1000:
        nb_primes = 1000

    len_p = 0  # The current number of elements in p.
    n = 2
    while len_p < nb_primes:
        # Is n prime?
        for i in p[:len_p]:
            if n % i == 0:
                break

        # If no break occurred in the loop, we have a prime.
        else:
            p[len_p] = n
            len_p += 1
        n += 1

    # 将函数返回值变成python中的list
    result_as_list  = [prime for prime in p[:len_p]]
    return result_as_list

然后，我们用C++写一个同样的函数

# distutils: language=c++
# 需要指定编译语言为c++，否则会按照c来编译
# 文件：primes_cpp.pyx

from libcpp.vector cimport vector # 导入C++中的Vector

def primes(unsigned int nb_primes):
    cdef int n, i
    cdef vector[int] p 
    p.reserve(nb_primes) # 设置容器容量为nb_primes

    n = 2
    while p.size() < nb_primes:
        for i in p:
            if n % i == 0:
                break
        
        else:   # 如果n没有被现有素数整除，说明n是素数
            p.push_back(n) # 将素数加入到p中
        n += 1
    
    return p # Vector可以和list进行直接导出

可见，C++中的vector和python中list是非常类似的，因此，返回list的时候，可以直接返回p这个vector，但是在c的实现中，我们必须进行一次类型转换。
（注意python中的for...else...用法）
** 注**：C++版本的Cython文件是不可以用pyximport方式进行动态编译的。
写一个编译文件：

from setuptools import setup
from Cython.Build import cythonize

setup(
    ext_modules=cythonize(['primes_cpp.pyx',
                            'primes_c.pyx'],
                          annotate=True # 生成 html格式的编译结果注释
                          )    
)

然后可以看一下两种实现的效率：
python -m timeit -s "from primes_c import primes" "primes(1000)"
python -m timeit -s "from primes_cpp import primes" "primes(1000)"
我发现C比C++还是要快，毕竟C++这里用的是vector这种动态数组。