OpenGL光照篇--光照贴图--12
参考：这里
上一节的材质只能设置物体表面一种颜色，所以我们需要贴图来设置不同位置不同颜色。
其实就采样贴图获取物体的相应颜色。
程序：
#include 顶点着色器：
#version 330 core
layout(location=0)in vec3 aPos;
layout(location=1)in vec3 aNormal;
layout(location=2)in vec2 aTexcoord;
out vec3 normal;
out vec3 fragPos;
out vec2 uv;
uniform mat4 model;
uniform mat4 view;
uniform mat4 projection;
void main()
{
gl_Position=projection*view*model*vec4(aPos,1.0);
fragPos=vec3(model*vec4(aPos,1.0));
normal=mat3(transpose(inverse(model)))*aNormal;
uv=aTexcoord;
}
片元着色器：添加了自发光贴图
#version 330 core
out vec4 fragColor;
struct Material
{
sampler2D diffuse;
sampler2D specular;
sampler2D emission;
float shininess;
};
struct Light
{
vec3 position;
vec3 ambient;
vec3 diffuse;
vec3 specular;
};
uniform Light light;
uniform Material material;
in vec2 uv;
in vec3 normal;
in vec3 fragPos;
uniform float offsetX;
uniform float offsetY;
uniform vec3 lightColor;
uniform vec3 lightPos;
uniform vec3 viewPos;
void main()
{
vec3 worldNormal=normalize(normal);
vec3 lightDir=normalize(light.position-fragPos);
vec3 viewDir=normalize(viewPos-fragPos);
vec3 albedo=texture(material.diffuse,uv).rgb;
vec3 specularMask=texture(material.specular,uv).rgb;
vec3 emission=texture(material.emission,vec2(uv.x-offsetX,uv.y-offsetY)).rgb;
//环境光
vec3 ambient=light.ambient*albedo;
//漫反射
float dif=max(dot(worldNormal,lightDir),0.0);
vec3 diffuse=light.diffuse*dif*albedo;
//高光
vec3 reflectDir=reflect(-lightDir,worldNormal);
float spe=pow(max(dot(viewDir,reflectDir),0.0),material.shininess);
vec3 specular=light.specular*spe*specularMask;
vec3 finalColor=ambient+diffuse+specular+emission;
fragColor=vec4(finalColor,1.0);
}