Eclipse开发调试ARM裸机程序(四)赤裸裸的代码拷贝
Eclipse开发调试ARM裸机程序(四)赤裸裸的代码拷贝
在u-boot中有代码拷贝，所谓的移植都是看着高手们现成的代码照搬过来，没有问题就代表自己移植成功了，我也是这样的。但是这些代码真正的做了些什么，不知道，调试u-boot时候也想把这段代码调试一下，当时没有成功，这次裸机要见下它的真面目了。
我还达不到自己去写一个拷贝代码的程度，不过要是能把一个拷贝代码理解的很清楚也是很有帮助的。下面我就是这样做的，用eclipse单步调试拷贝代码，查看内存变化，切实感受代码拷贝。先上代码：
@*************************************************************************
@ File：head.S
@ 功能：设置SDRAM，将程序复制到SDRAM，然后跳到SDRAM继续执行
@*************************************************************************
.equ MEM_CTL_BASE, 0x48000000
.equ SDRAM_BASE, 0x30000000
.text
.global _start
_start:
bl disable_watch_dog @ 关闭WATCHDOG，否则CPU会不断重启
bl memsetup @ 设置存储控制器
bl copy_steppingstone_to_sdram @ 复制代码到SDRAM中
ldr pc, =on_sdram @ 跳到SDRAM中继续执行
on_sdram:
ldr sp, =0x34000000 @ 设置堆栈
bl main
halt_loop:
b halt_loop
disable_watch_dog:
@ 往WATCHDOG寄存器写0即可
mov r1, #0x53000000
mov r2, #0x0
str r2, [r1]
mov pc, lr @ 返回
copy_steppingstone_to_sdram:
@ 将Steppingstone的4K数据全部复制到SDRAM中去
@ Steppingstone起始地址为0x00000000，SDRAM中起始地址为0x30000000
mov r1, #0
ldr r2, =SDRAM_BASE
mov r3, #4*1024
1:
ldr r4, [r1],#4 @ 从Steppingstone读取4字节的数据，并让源地址加4
str r4, [r2],#4 @ 将此4字节的数据复制到SDRAM中，并让目地地址加4
cmp r1, r3 @ 判断是否完成：源地址等于Steppingstone的未地址？
bne 1b @ 若没有复制完，继续
mov pc, lr @ 返回
memsetup:
@ 设置存储控制器以便使用SDRAM等外设
mov r1, #MEM_CTL_BASE @ 存储控制器的13个寄存器的开始地址
adrl r2, mem_cfg_val @ 这13个值的起始存储地址
add r3, r1, #52 @ 13*4 = 54
1:
ldr r4, [r2], #4 @ 读取设置值，并让r2加4
str r4, [r1], #4 @ 将此值写入寄存器，并让r1加4
cmp r1, r3 @ 判断是否设置完所有13个寄存器
bne 1b @ 若没有写成，继续
mov pc, lr @ 返回
.align 4
mem_cfg_val:
@ 存储控制器13个寄存器的设置值
.long 0x22011110 @ BWSCON
.long 0x00000700 @ BANKCON0
.long 0x00000700 @ BANKCON1
.long 0x00000700 @ BANKCON2
.long 0x00000700 @ BANKCON3
.long 0x00000700 @ BANKCON4
.long 0x00000700 @ BANKCON5
.long 0x00018005 @ BANKCON6
.long 0x00018005 @ BANKCON7
.long 0x008C07A3 @ REFRESH
.long 0x000000B1 @ BANKSIZE
.long 0x00000030 @ MRSRB6
.long 0x00000030 @ MRSRB7
#define GPBCON (*(volatile unsigned long *)0x56000010)
#define GPBDAT (*(volatile unsigned long *)0x56000014)
#define GPB5_out (1<<(5*2))
#define GPB6_out (1<<(6*2))
#define GPB7_out (1<<(7*2))
#define GPB8_out (1<<(8*2))
void wait(unsigned long dly)
{
for(; dly > 0; dly--);
}
int main(void)
{
unsigned long i = 0;
GPBCON = GPB5_out|GPB6_out|GPB7_out|GPB8_out; // 将LED1-4对应的GPB5/6/7/8四个引脚设为输出
while(1){
wait(30000);
GPBDAT = (~(i<<5)); // 根据i的值，点亮LED1-4
if(++i == 16)
i = 0;
}
return 0;
}
all : head.S leds.c arm-linux-gcc -c -g -o head.o head.S arm-linux-gcc -c -g -o leds.o leds.c arm-linux-ld -Ttext 0x00000000 head.o leds.o -o sdram_elf arm-linux-objcopy -O binary -S sdram_elf sdram.bin arm-linux-objdump -D -m arm sdram_elf > sdram.dis clean: rm -f sdram.dis sdram.bin sdram_elf *.o
原本Makefile中没有加-g这使我很郁闷，能用elf调试但是什么断点都不能打。以前没有注意这个问题。原链接地址是0x30000000,我改为0x0这位就可以在内部ram中调试。下边看看内部ram拷贝到sdram的效果图：
copy之前：
copy之后：
1.要想看到拷贝效果，调试之前要先断电上电一下，这位sdram中的内容就丢失变为0xff。不然上次拷贝过的东西还有，就看不到效果了。
2.还有一点遗憾，就是我把链接地址改为0x00000000后，在程序中跳到main时，实际上还在内部ram中。我无法跳到SDRAM，因为我直接写一个绝对地址0x3000000e8,编译都不让我过的。反正通过图能看到确实拷贝过来了，这是从sram到sdram中的拷贝方法，可以为以后从NorFlash拷贝和从NandFlash拷贝到甚至SD卡中拷贝到ram中垫下了基础。
这个程序要想下载运行，把链接地址改为0x30000000 －（内存大小）范围内应该都没有问题。
这也得出了，u-boot的启动原理，链接时候只管链接到内存中的地址（0x33F80000），当下载到NandFlash中运行的时候，只用相对跳转指令（就像在大街上左走20米，右走20米），这样欺骗代码，不让它知道自己在哪里。到内存初始化好了，代码拷贝过去之后。突然来个绝对跳转到SDRAM中（就像在大街上前门大街15号）。这也是如果把链接地址改成的0x0是能调试了，但是就不能跳转SDRAM中了。目前不能，不知道以后能不能。