Vijos-p1037 2008.11.7

Vijos-p1037 2008.11.7

描述 Description  

2001年9月11日，一场突发的灾难将纽约世界贸易中心大厦夷为平地，Mr. F曾亲眼目睹了这次灾难。为了纪念“9?11”事件，Mr. F决定自己用水晶来搭建一座双塔。

Mr.F有N块水晶，每块水晶有一个高度，他想用这N块水晶搭建两座有同样高度的塔，使他们成为一座双塔，Mr. F可以从这N块水晶中任取M（1≤M≤N）块来搭建。但是他不知道能否使两座塔有同样的高度，也不知道如果能搭建成一座双塔，这座双塔的最大高度是多少。所以他来请你帮忙。

给定水晶的数量N（1≤N≤100）和每块水晶的高度Hi（N块水晶高度的总和不超过2000），你的任务是判断Mr. F能否用这些水晶搭建成一座双塔（两座塔有同样的高度），如果能，则输出所能搭建的双塔的最大高度，否则输出“Impossible”。

输入格式 Input Format 

输入的第一行为一个数N，表示水晶的数量。第二行为N个数，第i个数表示第i个水晶的高度。

输出格式 Output Format 

输出仅包含一行，如果能搭成一座双塔，则输出双塔的最大高度，否则输出一个字符串“Impossible”。

样例输入 Sample Input  

5

13 4 5 2

样例输出 Sample Output  

7

 

以水晶为阶段，每阶段决策一块水晶，以双塔的高度差为状态，这样不难写出状态转移方程：用f[i,j]表示前i块水晶，高塔与较低塔高度差为j时，较低塔的最大高度，(题目让求什么，就决策什么)因此可以得到基本递推方程：

f[i,j]=max{f[i-1,j]（不加）,f[i-1,j+h[i]]（给高塔加上）,f[i-1,h[i]-j]+j（低塔加上后，比高塔高）,f[i-1,j-h[i]]+h[i]（给低塔加上）}

（找到阶段后，看都有哪些量才能把他推出来，都有哪些选择）

其中1≤i≤n，边界条件f[0,0]=0。得到了这个递推式，不难写出程序，代码如下：

[参考程序]

program ex2(input,output);
var
f:array[0..100,0..2000] of smallint;
h:array[1..100] of smallint;
i,j,n,sum:smallint;
begin
readln(n);  sum:=0;
for i:=1 to n do begin read(h[i]); sum:=sum+h[i]; end;
fillchar(f,sizeof(f),255);
f[0,0]:=0;{边界条件}
for i:=1 to n do
for j:=0 to sum do
if f[i-1,j]<>-1 then begin
if f[i-1,j]>f[i,j] then f[i,j]:=f[i-1,j];
if f[i-1,j]>f[i,j+h[i]] then f[i,j+h[i]]:=f[i-1,j];
if j>=h[i] then begin
if f[i-1,j]+h[i]>f[i,j-h[i]] then f[i,j-h[i]]:=f[i-1,j]+h[i];
end
           else begin
if f[i-1,j]+j>f[i,h[i]-j] then f[i,h[i]-j]:=f[i-1,j]+j;
end;
end;
if f[n,0]>0 then write(f[n,0])
            else write('Impossible');
{若f[n,0]=-1表示不能使高度差为0 ，故输出无解}
end.

1.       错误的方法：

program p_1037;
const maxn=100;maxm=2000;
var a:array[1..100]of longint;
      f:array[0..maxm]of longint;
      i,j,n,m,max,k:longint;
begin fillchar(f,sizeof(f),0);
        read(n);m:=0;max:=0;f[0]:=1;
        for i:=1 to n do begin read(a[i]);inc(m,a[i])end;
        m:=m div 2;
        for j:=1 to n do
          for i:=m downto 1 do
              if(i-a[j]>=0)and(f[i-a[j]]>0)then inc(f[i]);
       for i:=0 to m do if f[i]>1 then max:=i;
          writeln(max);
end.

错因：这样dp下来的，如果把题目改成，用n块积木搭塔每种只能用一个，到达多大高度的时候，高度h的方案不止有一种。我的这个算法，虽然每个搭塔方案都是每个积木至多用一次，不同方案间的积木有重复使用，

当h相同时，也是一样如：

  1 23 4 5 à15

  1 68 à15    虽然都是15，但都用了1，故错。