在给Box2DFlash中的形状赋予纹理之前，缺省采用DebugDraw方式绘制形状。DebugDraw由若干标志位组成：
e_shapeBit：绘制形状轮廓
e_jointBit：绘制关节的节点和连接线
e_aabbBit：绘制轴对齐边界框（axis aligned bounding boxes）
e_controllerBit：绘制控制器
e_pairBit: 绘制宽相对
e_centerOfMassBit：绘制质量的中心
示例代码如下：

package{
	import Box2D.Collision.Shapes.b2CircleShape;
	import Box2D.Collision.Shapes.b2PolygonShape;
	import Box2D.Collision.Shapes.b2Shape;
	import Box2D.Collision.b2AABB;
	import Box2D.Common.Math.b2Vec2;
	import Box2D.Dynamics.Joints.b2MouseJoint;
	import Box2D.Dynamics.Joints.b2MouseJointDef;
	import Box2D.Dynamics.b2Body;
	import Box2D.Dynamics.b2BodyDef;
	import Box2D.Dynamics.b2DebugDraw;
	import Box2D.Dynamics.b2Fixture;
	import Box2D.Dynamics.b2FixtureDef;
	import Box2D.Dynamics.b2World;
 
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
 
	[SWF(width="800",height="600",frameRate="32",backgroundColor="0x000000")]
	public class DebugDraw extends Sprite{
		private var world:b2World;
		private var body:b2Body;
		private var timeStep:Number;
		private var iterations:uint;
		private var pixelsPerMeter:Number = 30;
		private var mouseJoint:b2MouseJoint;
		private var mousePVec:b2Vec2 = new b2Vec2();
 
		public function DebugDraw(){
			createWorld();
			makeDebugDraw();
			createWall();
			createBodies();
			addEventListener(Event.ENTER_FRAME,onEnterframe);
			stage.addEventListener(MouseEvent.MOUSE_DOWN,onMouseDown);
			stage.addEventListener(MouseEvent.MOUSE_UP,onMouseUp);
		}
 
		private function createWorld():void{
			var gravity:b2Vec2 = new b2Vec2(0.0,9.8);
			var doSleep:Boolean = true;
			world = new b2World(gravity,doSleep);
			world.SetWarmStarting(true);
			timeStep = 1.0/30.0;
			iterations = 10;
		}
 
		private function makeDebugDraw():void{
			var debugDraw:b2DebugDraw = new b2DebugDraw();
			var debugSprite:Sprite = new Sprite();
			addChild(debugSprite);
			debugDraw.SetSprite(debugSprite);
			debugDraw.SetDrawScale(30.0);
			debugDraw.SetFillAlpha(0.5);
			debugDraw.SetLineThickness(1.0);
			debugDraw.SetFlags(b2DebugDraw.e_shapeBit | b2DebugDraw.e_jointBit |
								b2DebugDraw.e_controllerBit | b2DebugDraw.e_aabbBit |
								b2DebugDraw.e_centerOfMassBit | b2DebugDraw.e_pairBit);
			world.SetDebugDraw(debugDraw);
		}
 
 
		private function createWall():void{
			var bodyDef:b2BodyDef = new b2BodyDef();
			// Body的中心点
			bodyDef.position.Set(400/pixelsPerMeter,585/pixelsPerMeter);
			body = world.CreateBody(bodyDef);
			var shape:b2PolygonShape = new b2PolygonShape();
			// 几何体的半宽和半高
			shape.SetAsBox(400/pixelsPerMeter,15/pixelsPerMeter);
			body.CreateFixture2(shape);
		}
 
		private function createBodies():void{
			for(var i:int=0;i<10;i++){
				var bodyDef:b2BodyDef = new b2BodyDef();
				bodyDef.type = b2Body.b2_dynamicBody;
				bodyDef.position.x = (Math.random()*600+120)/pixelsPerMeter;
				bodyDef.position.y = (Math.random()*150)/pixelsPerMeter;
				var hx:Number = (Math.random()*30+15)/pixelsPerMeter;
				var hy:Number = (Math.random()*30+15)/pixelsPerMeter;
				var fixtureDef:b2FixtureDef = new b2FixtureDef();
				fixtureDef.density = 1.0;
				fixtureDef.friction = 0.5;
				fixtureDef.restitution = 0.2;
				if(Math.random()<0.5){
					var square:b2PolygonShape = new b2PolygonShape();
					square.SetAsBox(hx,hy);
					fixtureDef.shape = square;
					body = world.CreateBody(bodyDef);
					body.CreateFixture(fixtureDef);
				}
				else{
					var circle:b2CircleShape = new b2CircleShape();
					circle.SetRadius(hx);
					fixtureDef.shape = circle;
					body = world.CreateBody(bodyDef);
					body.CreateFixture(fixtureDef);
				}
			}
		}
 
		private function onMouseDown(e:MouseEvent):void{
			var body:b2Body = getBodyAtMouse();
			if(body){
				// 建立MouseJoint定义
				var mouseJointDef:b2MouseJointDef = new b2MouseJointDef();
				// bodyA为无碰撞检测的静态刚体
				mouseJointDef.bodyA = world.GetGroundBody();
				// bodyB为当前检测到被点击的刚体
				mouseJointDef.bodyB = body;
				// 设置MouseJoint的最初世界位置
				mouseJointDef.target.Set(mouseX/pixelsPerMeter,mouseY/pixelsPerMeter);
				mouseJointDef.maxForce = 30000;
				mouseJoint = world.CreateJoint(mouseJointDef) as b2MouseJoint;
			}
		}
 
		private function onMouseUp(e:MouseEvent):void{
			if(mouseJoint){
				world.DestroyJoint(mouseJoint);
				mouseJoint = null;
			}
		}
 
		private function getBodyAtMouse(includeStatic:Boolean = false):b2Body{
			var mouseXWorldPhys:Number = mouseX/pixelsPerMeter;
			var mouseYWorldPhys:Number = mouseY/pixelsPerMeter;
			mousePVec.Set(mouseXWorldPhys,mouseYWorldPhys);
			// 利用当前鼠标向量建立一个很小的b2AABB
			var aabb:b2AABB = new b2AABB();
			aabb.lowerBound.Set(mouseXWorldPhys-0.001,mouseYWorldPhys-0.001);
			aabb.upperBound.Set(mouseXWorldPhys+0.001,mouseYWorldPhys+0.001);
			var body:b2Body = null;
			var fixture:b2Fixture;
			function GetBodyCallBack(fixture:b2Fixture):Boolean{
				var shape:b2Shape = fixture.GetShape();
				if(fixture.GetBody().GetType() != b2Body.b2_staticBody || includeStatic){
					var inside:Boolean = shape.TestPoint(fixture.GetBody().GetTransform(),mousePVec);
					if(inside){
						body = fixture.GetBody();
						return false;
					}
				}
				return true;
			}
			// 在World中查找与鼠标向量定义的Shape相重叠的Shape 
			world.QueryAABB(GetBodyCallBack,aabb);
			return body;
		}
 
		private function onEnterframe(e:Event):void{
			world.Step(timeStep,iterations,iterations);
			world.ClearForces();
			world.DrawDebugData();
			if(mouseJoint){
				var xpos:Number = mouseX/pixelsPerMeter;
				var ypos:Number = mouseY/pixelsPerMeter;
				var v2:b2Vec2 = new b2Vec2(xpos,ypos);
				mouseJoint.SetTarget(v2);
			}
		}
	}
}

DebugDraw_第1张图片