本文同时发布在我的个人博客上：https://dragon_boy.gitee.io
这一章我们使用之前讲解过的PBR理论进行使用直接光源(点光源、平行光、聚光灯等)的光照渲染。
先给出反射方程:
上述方程计算的是总的辐射率，也就是辐照率，而每个辐射率是根据一个给定的立体角测量的辐射通量，我们可以近似立体角无限小为一个方向向量来测量辐射通量。
那么如何将上面的理论转化为实际的光照模拟。我们首先想象一个点光源，自带一个辐射通量(23.47, 21.31, 20.79)(已经转化为RGB模式)，这个光源的辐射强度就等于它所有射出光线方向的辐射通量总和 。在考虑某一点的光照时，对于所有在其半球内的光线，只有一条来自光源方向的的入射光线对点进行了着色。这样的话，只考虑空间中有一点的光照，也就可以只考虑一个方向的光照着色，其它方向的入射光可以考虑为0辐射率：
假设我们先不考虑光的衰减，这样就可以任意摆放光源的位置(除去用入射角调整辐射率)。由于在这种假设情况下，在任何方向观察，光的辐射强度都是不变的，我们就可以使用它的辐射通量来作为它的辐射强度(23.47, 21.31, 20.79)。
不过在反射方程中，辐射率实际也由光照作用点位置决定，也就是要把光的衰减考虑在内，辐射强度由点和光源距离通过某种方式进行缩放。从原反射方程可以得出，结果是由表面法线和入射光方向的点积进行缩放的。
根据上面的说法，在实际计算中，反射方程的可以用来代表光的颜色，通过光源到的距离衰减，结果通过缩放，在GLSL中这样表示：
vec3 lightColor = vec3(23.47, 21.31, 20.79);
vec3 wi = normalize(lightPos - fragPos);
float cosTheta = max(dot(N, Wi), 0.0);
float attenuation = calculateAttenuation(fragPos, lightPos);
vec3 radiance = lightColor * attenuation * cosTheta;
注意，上述的代码只适用于点光源被考虑为无限小的情况，若是针对一定体积的点光源，我们要考虑更多入射光方向的辐射通量，不能单纯地置为0。
通过上面的点光源的理论，我们还可以拓展到平行光和聚光灯，比如平行光的入射光方向是一个常量，不考虑光的衰减；聚光灯的辐射强度不是一个常量，会通过聚光等的方向向量进行缩放。
PBR表面模型
我们首先根据前面的理论在片元着色器中实现PBR模型，首先，设置相关输入变量和uniform变量：
#version 330 core
out vec4 FragColor;
in vec2 TexCoords;
in vec3 WorldPos;
in vec3 Normal;
uniform vec3 camPos;
uniform vec3 albedo;
uniform float metallic;
uniform float roughness;
uniform float ao;
接着计算法线和观察方向：
void main()
{
vec3 N = normalize(Normal);
vec3 V = normalize(camPos - WorldPos);
[...]
}
这里我们将使用4个点光源来照亮场景，我们首先遍历每个光源，计算单独的辐射率，接着通过BRDF和光的入射角缩放，最后合并起来。在循环中，我们先计算好每个光源公用的变量：
vec3 Lo = vec3(0.0);
for(int i = 0; i < 4; ++i)
{
vec3 L = normalize(lightPositions[i] - WorldPos);
vec3 H = normalize(V + L);
float distance = length(lightPositions[i] - WorldPos);
float attenuation = 1.0 / (distance * distance);
vec3 radiance = lightColors[i] * attenuation;
[...]
由于我们在线性空间计算光照，我们通过平方反比定律来衰减光照（物理正确）。
我们也可以使用之前学过的<<常量-线性-平方>>衰减等式来进行衰减
接着对每个光源我们使用 Cook-Torrance BRDF：
不过首先我们要计算反射和折射的比例，这通过菲涅尔等式计算：
vec3 fresnelSchlick(float cosTheta, vec3 F0)
{
return F0 + (1.0 - F0) * pow(1.0 - cosTheta, 5.0);
}
菲涅尔等式将基本反射率作为参数。
在main函数中，我们首先将基本反射率定位0.04，这适用于大多数的非金属材质，接着我们根据设置的金属度与表面颜色进行混合，以达到金属和非金属之间的切换，接着用上述菲涅尔等式计算反射的比例：
vec3 F0 = vec3(0.04);
F0 = mix(F0, albedo, metallic);
vec3 F = fresnelSchlick(max(dot(H, V), 0.0), F0);
计算完反射的部分后，还剩下D和G，即发现分布函数和几何函数。
在PBR理论那一章介绍过D和G的实现：
float DistributionGGX(vec3 N, vec3 H, float roughness)
{
float a = roughness*roughness;
float a2 = a*a;
float NdotH = max(dot(N, H), 0.0);
float NdotH2 = NdotH*NdotH;
float num = a2;
float denom = (NdotH2 * (a2 - 1.0) + 1.0);
denom = PI * denom * denom;
return num / denom;
}
float GeometrySchlickGGX(float NdotV, float roughness)
{
float r = (roughness + 1.0);
float k = (r*r) / 8.0;
float num = NdotV;
float denom = NdotV * (1.0 - k) + k;
return num / denom;
}
float GeometrySmith(vec3 N, vec3 V, vec3 L, float roughness)
{
float NdotV = max(dot(N, V), 0.0);
float NdotL = max(dot(N, L), 0.0);
float ggx2 = GeometrySchlickGGX(NdotV, roughness);
float ggx1 = GeometrySchlickGGX(NdotL, roughness);
return ggx1 * ggx2;
接着在循环中计算NDF和G的部分：
float NDF = DistributionGGX(N, H, roughness);
float G = GeometrySmith(N, V, L, roughness);
接着计算BRDF：
vec3 numerator = NDF * G * F;
float denominator = 4.0 * max(dot(N, V), 0.0) * max(dot(N, L), 0.0);
vec3 specular = numerator / max(denominator, 0.001);
注意我们将分母控制在0.001内，以免分母为0。
在反射方程中，我们将菲涅尔等式的结果F作为反射比率，我们可以根据这个计算折射比率：
vec3 kS = F;
vec3 kD = vec3(1.0) - kS;
kD *= 1.0 - metallic;
由于我们不考虑金属表面的折射，所以我们*=1-metallic来消除金属部分的折射。
最后，就可以计算每个光源的反射率，并逐一相加得到反照率：
const float PI = 3.14159265359;
float NdotL = max(dot(N, L), 0.0);
Lo += (kD * albedo / PI + specular) * radiance * NdotL;
}
最后输出颜色的时候记得加上环境光：
vec3 ambient = vec3(0.03) * albedo * ao;
vec3 color = ambient + Lo;
在上面的计算中我们都是在线性空间中进行的，所以我们需要进行伽马矫正。在之前讲解AO时，我们知道它本身是一个超出LDR范围的值，即HDR范围，如果单纯的截取LDR的范围的话，AO值会很高，所以在进行伽马矫正前需要先将其通过色调映射合理的转化到LDR的范围：
color = color / (color + vec3(1.0)); //莱因哈特方法
color = pow(color, vec3(1.0/2.2));
最后，完整的片元着色器如下：
#version 330 core
out vec4 FragColor;
in vec2 TexCoords;
in vec3 WorldPos;
in vec3 Normal;
// material parameters
uniform vec3 albedo;
uniform float metallic;
uniform float roughness;
uniform float ao;
// lights
uniform vec3 lightPositions[4];
uniform vec3 lightColors[4];
uniform vec3 camPos;
const float PI = 3.14159265359;
float DistributionGGX(vec3 N, vec3 H, float roughness);
float GeometrySchlickGGX(float NdotV, float roughness);
float GeometrySmith(vec3 N, vec3 V, vec3 L, float roughness);
vec3 fresnelSchlick(float cosTheta, vec3 F0);
void main()
{
vec3 N = normalize(Normal);
vec3 V = normalize(camPos - WorldPos);
vec3 F0 = vec3(0.04);
F0 = mix(F0, albedo, metallic);
// reflectance equation
vec3 Lo = vec3(0.0);
for(int i = 0; i < 4; ++i)
{
// calculate per-light radiance
vec3 L = normalize(lightPositions[i] - WorldPos);
vec3 H = normalize(V + L);
float distance = length(lightPositions[i] - WorldPos);
float attenuation = 1.0 / (distance * distance);
vec3 radiance = lightColors[i] * attenuation;
// cook-torrance brdf
float NDF = DistributionGGX(N, H, roughness);
float G = GeometrySmith(N, V, L, roughness);
vec3 F = fresnelSchlick(max(dot(H, V), 0.0), F0);
vec3 kS = F;
vec3 kD = vec3(1.0) - kS;
kD *= 1.0 - metallic;
vec3 numerator = NDF * G * F;
float denominator = 4.0 * max(dot(N, V), 0.0) * max(dot(N, L), 0.0);
vec3 specular = numerator / max(denominator, 0.001);
// add to outgoing radiance Lo
float NdotL = max(dot(N, L), 0.0);
Lo += (kD * albedo / PI + specular) * radiance * NdotL;
}
vec3 ambient = vec3(0.03) * albedo * ao;
vec3 color = ambient + Lo;
color = color / (color + vec3(1.0));
color = pow(color, vec3(1.0/2.2));
FragColor = vec4(color, 1.0);
}
下面是使用这个片元着色器渲染的一些例子(4个光源，拥有不同金属度和粗糙度的一些球体)：
从上到下，金属度由0到1递增，从左到右，粗糙度由0到1递增。
这里给出原文代码参考：Code。
PBR纹理
若要在PBR流程中使用纹理，我们需要将albedo、normal、metallic、roughness、ao这些参数使用纹理采样：
[...]
uniform sampler2D albedoMap;
uniform sampler2D normalMap;
uniform sampler2D metallicMap;
uniform sampler2D roughnessMap;
uniform sampler2D aoMap;
void main()
{
vec3 albedo = pow(texture(albedoMap, TexCoords).rgb, 2.2);
vec3 normal = getNormalFromNormalMap();
float metallic = texture(metallicMap, TexCoords).r;
float roughness = texture(roughnessMap, TexCoords).r;
float ao = texture(aoMap, TexCoords).r;
[...]
}
注意到albedo颜色纹理大多数时候是在sRGB空间制作的，所以我们首先将其转化到线性空间（注意！PBR必须在线性空间计算光照，否则结果不准确），AO图也可能在sRGB空间进行制作的，所以按情况判断。
下面是使用一些纹理的PBR光照例子：
这里给出原文代码参考：Code。
最后，贴出原文链接供参考：https://learnopengl.com/PBR/Lighting。