Lambert 光照模型

Shader "Custom/Chapter6-HalfLambert" {

    Properties {
        _Diffuse ("Diffuse",Color) = (1,1,1,1)
    }

    SubShader {
        Pass {

            Tags { "LightMode" = "ForwardBase" }

            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            fixed4 _Diffuse;

            struct a2v {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f {
                float4 pos : SV_POSITION;
                fixed3 worldNormal : TEXCOORD0;
            };

            // 从应用到顶点着色器
            v2f vert (a2v v){
                v2f o;
                // 从将顶点从模型空间转换到裁剪空间
                o.pos = UnityObjectToClipPos(v.vertex);
                // 将世界空间下的法线传递给片元着色器
                o.worldNormal = mul(v.normal,(float3x3)unity_WorldToObject);
                return o;
            }

            // 从顶点着色器到偏远着色器
            fixed4 frag(v2f i) : SV_TARGET {

                // 获取环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                // 获取法线
                fixed3 worldNormal = normalize(i.worldNormal);
                // 获取光源方向
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                // Lambert公式
                fixed halfLambert = dot(worldNormal,worldLightDir) * 0.5 + 0.5;
                // 计算漫反射光
                fixed3 difuse = _LightColor0.rgb * _Diffuse.rgb * halfLambert;
                // 添加环境光
                fixed3 color = ambient + difuse;

                return fixed4(color,1.0);
            }

            ENDCG
        }
    }

    FallBack "Diffuse"
}