翻译shader(4)

// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'
//https://www.cnblogs.com/kanekiken/p/7616700.html
//逐顶点
Shader "Unity Shaders Book/Chapter 6/Diffuse Vertex-Level" {
	Properties {
		_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
	}
	SubShader {
		Pass { 
		//LightMode决定了光照模式，该标签可用的值我们暂时只需要知道两个，ForwardBase和ForwardAdd，
		//LightMode设为ForwardBase，那么Unity就知道我们需要平行光的光源信息，接下来，_LightColor0也就代表平行光的光源强度，_WorldSpaceLightPos也就代表平行光的方向
		// /* 在pass块中设定的的标签只能在Tags中有效，如果pass中出现了和SubShader中同样的标签，则会覆盖SubShader中的标签。此处我们使用了ForwardBase，也就是这个光照模型只对平行光有效* /
			Tags { "LightMode"="ForwardBase" }
		
			CGPROGRAM
			
			#pragma vertex vert
			#pragma fragment frag
			
			#include "Lighting.cginc"
			
			fixed4 _Diffuse;
			
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
			};
			
			struct v2f {
				float4 pos : SV_POSITION;
				fixed3 color : COLOR;
			};
			
			v2f vert(a2v v) {
				v2f o;
				//模型空间到剪裁空间
				o.pos = UnityObjectToClipPos(v.vertex);
				
				//我们通过Unity的内置变量UNITY_LIGHTMODEL_AMBIENT 得到了环境光部分
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
				
				//将光源转换到世界
				fixed3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
				//得到光源方向，并且归一化,这里对光源方向的计算并不具有通用性,需要转换同一个坐标系
				fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
				//			      环境光强度        漫反射系数     我们使用saturate函数   //把参数截取到[0, 1]范围内。
				//saturate(dot))为了防止出现负数,：https://www.sohu.com/a/166481608_667928
				fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));
				//			环境光+反射光
				o.color = ambient + diffuse;
				
				return o;
			}
			
			fixed4 frag(v2f i) : SV_Target {
				return fixed4(i.color, 1.0);
			}
			
			ENDCG
		}
	}
	FallBack "Diffuse"
}