翻译Shader(7)---渐变贴图

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "BBBBBBBBBB/贴图/03---渐变贴图" {
	Properties{
		_Color("Color Tint", Color) = (1, 1, 1, 1)
		_RampTex("Ramp Tex", 2D) = "white" {}
		_Specular("Specular", Color) = (1, 1, 1, 1)
		_Gloss("Gloss", Range(8.0, 256)) = 20
	}
		SubShader{
			Pass {
				Tags { "LightMode" = "ForwardBase" }

				CGPROGRAM

				#pragma vertex vert
				#pragma fragment frag

				#include "Lighting.cginc"

				fixed4 _Color;
				sampler2D _RampTex;
				float4 _RampTex_ST;
				fixed4 _Specular;
				float _Gloss;

				struct a2v {
					float4 vertex : POSITION;
					float3 normal : NORMAL;
				};

				struct v2f {
					float4 pos : SV_POSITION;
					float3 worldNormal : TEXCOORD0;
					float3 worldPos : TEXCOORD1;
				};

				v2f vert(a2v v) {
					v2f o;
					//将顶点从模型空间转换到裁剪空间
					o.pos = UnityObjectToClipPos(v.vertex);
					//将法线转换到世界空间
					o.worldNormal = UnityObjectToWorldNormal(v.normal);
					//点再世界空间中的位置	
					o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;

					return o;
				}

				fixed4 frag(v2f i) : SV_Target {
				//计算环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
				//序列化法线
				fixed3 worldNormal = normalize(i.worldNormal);
				//得到光源方向
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				//半兰伯特 漫反射计算
				fixed halfLambert = 0.5 * dot(worldNormal, worldLightDir) + 0.5;
				fixed3 diffuseColor = tex2D(_RampTex, fixed2(halfLambert,halfLambert)).rgb * _Color.rgb;
				fixed3 diffuse = _LightColor0.rgb * diffuseColor;
				//高光反射
				//获取点到摄像机的方向角度，视角方向
				fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
				//光源方向+视角方向？？？
				fixed3 halfDir = normalize(worldLightDir + viewDir);
				//dot(worldNormal, halfDir)?不应该是视角方向*反射角方向吗
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
				//环境光   +   漫反射   +高光
				return fixed4(ambient + diffuse + specular, 1.0);
			}

			ENDCG
		}
		}
			FallBack "Specular"
}